Update specific field on specific index

RE: Update specific field on specific index

Peter Lewis — Mon, 16 Aug 2021 12:53:46 GMT

You can still use a!update(), just use a!forEach() instead of the first update:

a!localVariables(
  local!data: {
    { index: 1, name: "John", lastName: "Doe" },
    { index: 2, name: "Henry", lastName: "Doe" },
    { index: 3, name: "Jenny", lastName: "Doe" },
  },
  a!forEach(
    items: local!data,
    expression: if(
      fv!index = 2,
      a!update(
        data: index(local!data, 2, {}),
        index: "name",
        value: "Jerry"
      ),
      if(
        fv!index = 3,
        a!update(
          data: index(local!data, 3, {}),
          index: "name",
          value: "Justine"
        ),
        fv!item
      )
    )
  )
)

RE: Update specific field on specific index

rainier_albario — Sat, 14 Aug 2021 02:14:05 GMT

Here

a!localVariables(
local!data: {
{ index: 1, name: "John", lastName: "Doe" },
{ index: 2, name: "Henry", lastName: "Doe" },
{ index: 3, name: "Jenny", lastName: "Doe" },
},
local!result: a!forEach(
items: local!data,
expression: if(
fv!index= 2,
updatedictionary(
fv!item,
{
name: "Jerome"
}
),
fv!item
)
),
a!forEach(
items: local!result,
expression: if(
fv!index= 3,
updatedictionary(
fv!item,
{
name: "Justine"
}
),
fv!item
)
)
)

RE: Update specific field on specific index

rainier_albario — Sat, 14 Aug 2021 02:10:52 GMT

Okay. I tried calling another forEach to update the 3rd index and it worked. Just wanna know if that's a good way to do that?

RE: Update specific field on specific index

rainier_albario — Sat, 14 Aug 2021 02:01:51 GMT

Hello Peter, Thank you for your reply. I tried this but I can't update multiple data. ex. 2nd and 3rd index

RE: Update specific field on specific index

rainier_albario — Sat, 14 Aug 2021 01:36:23 GMT

Sorry for the late reply. I tried this

if the index is 1 and 2 the value should be both updated. but its not working as expected on my end only one can be updated.

RE: Update specific field on specific index

Chris — Fri, 13 Aug 2021 21:04:31 GMT

As an alternative for prior versions of Appian, the Dictionary Manipulation plugin is very useful for these sorts of things:

a!localVariables(
  local!data: {
    { index: 1, name: "John", lastName: "Doe" },
    { index: 2, name: "Henry", lastName: "Doe" },
    { index: 3, name: "Jenny", lastName: "Doe" },
  },
  
  a!forEach(
    items: local!data,
    expression: if(
      fv!index=2,
      updatedictionary(
        fv!item,
        {
          name: "Jerry"
        }
      ),
      fv!item
    )
  )
)

RE: Update specific field on specific index

Peter Lewis — Fri, 13 Aug 2021 20:55:20 GMT

Are you on 21.2? There's a great function that was recently released called a!update() that makes this pretty easy. The only tricky thing is that since you're updating a single value in a list of lists, you have to perform a!update() twice. Here's an example of how it works:

a!localVariables(
  local!data: {
    { index: 1, name: "John", lastName: "Doe" },
    { index: 2, name: "Henry", lastName: "Doe" },
    { index: 3, name: "Jenny", lastName: "Doe" },
  },
  a!update(
    data: local!data,
    index: 2,
    value: a!update(
      data: index(local!data, 2, {}),
      index: "name",
      value: "Jerry"
    ),
  )
)