RE: Appending Map with keys and values from second map

John Barker — Fri, 25 Oct 2024 13:41:30 GMT

Thank you so much Shanmathi! This worked like a charm! I was struggling with how to get the values array to line up with the keys that I wanted to add to the first map.

RE: Appending Map with keys and values from second map

Prasanta Paul — Fri, 25 Oct 2024 06:01:41 GMT

If you want to update, you can use a!update() function

RE: Appending Map with keys and values from second map

Shanmathi Ponnusamy — Fri, 25 Oct 2024 00:33:20 GMT

HI John Barker ,

You want all the keys and values in queueMap to be appened to corresponding participantMap. Please refer below code and is this what you expected.

a!localVariables(
  local!participantMap: {
    a!map(
      participantId: 3402,
      blockId: 881,
      policyNumber: "VF80U16350",
      policyEffectiveDate: fn!date(2023, 9, 25),
      dateOfBith: null,
      firstName: "Bill",
      lastName: " Johnson",
      middleInitial: "W",
      ssn: "123456789",
      genderRefId: 68,
      suffixRefId: 63,
      statusRefId: 1032
    ),
    a!map(
      participantId: 3401,
      blockId: 881,
      policyNumber: "VF80U16340",
      policyEffectiveDate: fn!date(2023, 9, 25),
      dateOfBith: fn!date(1996, 7, 4),
      firstName: "Robert",
      lastName: "Martinez",
      middleInitial: "J",
      ssn: "213456689",
      genderRefId: 69,
      suffixRefId: 66,
      statusRefId: 1093
    )
  },
  local!queueMap: {
    a!map(
      queueId: 3354,
      blockId: 881,
      participantId: 3402,
      appianGroupId: 58,
      assigneeUsername: "Karl.Seager@test.com",
      isActive: true,
      modifiedOn: fn!datetime(2024, 7, 18, 13, 31, 49, 0),
      lastAssignee: "",
      lastAssignedGroup: 25
    ),
    a!map(
      queueId: 3356,
      blockId: 881,
      participantId: 3401,
      appianGroupId: 58,
      assigneeUsername: "Karl.Seager@test.com",
      isActive: true,
      modifiedOn: fn!datetime(2024, 7, 18, 13, 31, 49, 0),
      lastAssignee: "",
      lastAssignedGroup: 25
    )
  },
  local!queueKeys: a!keys(index(local!queueMap, 1, {})),
  local!updatedMap: a!forEach(
    items: local!participantMap,
    expression: a!localVariables(
      local!currentParticipantItem: fv!item,
      local!currentParticipantQueue: index(
        local!queueMap,
        wherecontains(
          tointeger(
            index(
              local!currentParticipantItem,
              "participantId",
              null
            )
          ),
          tointeger(
            index(local!queueMap, "participantId", null)
          )
        ),
        null
      ),
      local!queueKeysValuesArray: a!forEach(
        items: local!queueKeys,
        expression: index(
          local!currentParticipantQueue,
          fv!item,
          null
        )
      ),
      a!update(
        fv!item,
        local!queueKeys,
        local!queueKeysValuesArray
      )
    )
  ),
  local!updatedMap
)