Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

nanfak — Wed, 21 Nov 2018 18:35:54 GMT

Thank you Mike Schmitt.

We truly appreciate this.

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

Mike Schmitt — Wed, 21 Nov 2018 18:14:34 GMT

Also since it was bugging me, I went ahead and created the "convert back to base 10" expression rule, which takes any positive baseX value (between base 2 and base 36), along with the specific base in question. Note it does minimal error handling but probably can't handle extended corner cases.

if(
  or(
    isnull(ri!xBaseNumberString),
    isnull(ri!base),
    ri!base > 36,
    ri!base < 2
  ),
  null(),
  
  with(
    local!charset: left("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ", ri!base),
    local!errorValue: -1,
    
    local!numCharacters: len(ri!xBaseNumberString),
    
    local!valueArray: a!forEach(
      items: reverse(enumerate(local!numCharacters)),
      
      expression: with(
        local!char: upper(ri!xBaseNumberString[fv!item + 1]),
        
        local!charPosition: find(local!char, local!charset),
        local!charValue: local!charPosition - 1,
        
        /* output: */
        if(
          local!charPosition = 0, /* try to handle the case of the number string having invalid characters */
          local!errorValue,
          local!charValue * (ri!base ^ (fv!index-1))
        )
      )
    ),
    
    if(
      contains(
        local!valueArray,
        local!errorValue
      ),
      tointeger(null()),
      sum(local!valueArray)
    )
    
    /* debug -- uncomment the following lines to see earlier calculated values */
    /*&char(10) & "numchars: " & local!numCharacters*/
  )
)

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

nanfak — Wed, 21 Nov 2018 16:46:58 GMT

Wow!!!

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

Mike Schmitt — Wed, 21 Nov 2018 14:44:40 GMT

For anyone who's interested, I was able to whip up this Appian expression rule last night, which uses 100% out-of-box functionality. In it, a user can pass any valid integer, as well as any base (between 2 and 36), and get the resulting conversion in a string. It performs fairly well, converting some of the largest allowable Appian integers into base 36 in only 2ms.

if(
  or(
    isnull(ri!base),
    isnull(ri!integer),
    ri!base > 36,
    ri!base < 2
  ),
  null(),
  
  with(
    local!base: ri!base,
    
    local!charset: left("0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZ", local!base),
    
    local!powerBase: log(ri!integer, local!base),
    local!numCharacters: ceiling(local!powerBase) + 1, /* the resulting number will need up to this many characters */
    
    
    local!strings: a!forEach(
      items: enumerate(local!numCharacters),
      
      expression: with(
        local!placeValue: ri!integer / (local!base ^ (fv!item)), /* requires zero-indexed list */
        
        local!charIndex: floor(mod(local!placeValue, local!base)),
        
        if(
          local!placeValue < 1,
          {},
          local!charset[local!charIndex+1]
        )
        
      )
    ),
    
    concat(reverse(local!strings))
    
    /* debug -- uncomment the following lines to see earlier calculated values */
    /*&char(10) & "power base: " & local!powerBase*/
    /*&char(10)& "places: " & local!numCharacters*/
  )
)

To convert back from a given base to base10 would just require an expression rule that does the reverse of this, which IMHO would actually be easier (edit: i've written this too and posted it below).

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

Mike Schmitt — Tue, 20 Nov 2018 15:11:22 GMT

To clarify a bit upon previous answers - this functionality would also be doable within an out-of-box expression rule if necessary, using normal internal Appian functions. It probably wouldn't perform 100% as well as a custom Java plug-in, but the advantage of doing it in an expression rule is that you could probably just write it yourself, using the expression language you already know, and without requiring plug-in hassles.

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

Roopesh Rambhatla — Tue, 20 Nov 2018 07:36:24 GMT

Most welcome .

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

nanfak — Tue, 20 Nov 2018 07:34:46 GMT

Thanks Roopesh. This was very helpful.

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

Roopesh Rambhatla — Mon, 19 Nov 2018 23:06:38 GMT

Hi Nanfak,

You have to get the plugin deployed to your environment. If Your environment is running in Cloud than simply go to Admin console and click on Plugins , Post that click on Deploy new plugin and search for "Execute Stored Procedure", and deploy same.
If you are running on-premise environment than download the jar from
"forum.appian.com/.../summary" and place the jar in the Plugin folder in the Server . It will take about a minute to get deployed.

Once the plugin is deployed you can use below mentioned sample expression to call the Stored Proc in Appian.

example :

with(
local!base36raw:executestoredprocedure(
"java:/jdbc/Appian",/*jndi Name can be found under the Data store or in Admin Console Dota Source */
"Appian.convert_to_36", /* format : schemaName.StoredProc Name */
{
{name: "numb",value:3634 }

}
),
local!base36value:index(local!base36raw.result,"conv(numb,10,36)",null),
local!base36value
)

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

nanfak — Mon, 19 Nov 2018 12:50:44 GMT

Thanks again Roopesh. How will I call this stored procedure in an expression rule?

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

nanfak — Mon, 19 Nov 2018 05:35:05 GMT

Thanks!

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

Roopesh Rambhatla — Mon, 19 Nov 2018 02:00:14 GMT

Hi nanfak,

There is an alternative, if your are using MySQL than there is function "select conv('3634',10,36)" which does the trick. so you can implement the solution using triggers, stored procedures or views.
Example : stored Proc Solution

DELIMITER //
CREATE PROCEDURE convert_to_36
(IN numb int)
BEGIN
select conv(numb,10,36);
END //
DELIMITER ;

Call call convert_to_36(3634)

You can do similar to convert from base 36 to base 10. Appian has a function which call the stored Procs in an Expression rule.

Hopefully it works for you.

Thanks Roopesh

RE: Convert base 10 to base 36 numbers using numbers 0 - 9 and letters A - Z

aloks0189 — Mon, 19 Nov 2018 01:52:52 GMT

Hi nanfak as per my understanding, we do not have any such functions available OOTB in Appian.

Hence i believe you need to build a Custom Plug-in (Expression Function) using java code, in order to achieve this requirement.

Hope this will help.