If Not Statement with @ Sign

RE: If Not Statement with @ Sign

Mike Schmitt — Tue, 30 Jul 2019 16:48:49 GMT

No prob - but just be aware (if it matters for your use case) that this logic will also allow a user to enter a lot of things that are not a valid email address - like "mike@", or "@test", or "mike@@test.com" (and various other incorrect permutations).

RE: If Not Statement with @ Sign

benjamins0003 — Tue, 30 Jul 2019 16:39:43 GMT

Perfect. Thanks

RE: If Not Statement with @ Sign

Mike Schmitt — Tue, 30 Jul 2019 16:27:34 GMT

If you're only interested in checking for the presence of the "@" in your validation (and validation message), then it's fairly easy to just use standard logic in the Validations: parameter of your text input field.

It would be accomplished with code similar to this:

a!textField(
  value: ri!email,
  saveInto: ri!email,
  validations: {
    if(
      not(like(ri!email, "*@*")),
      "email address must contain an '@' sign.",
      null()
    )
  }
)

RE: If Not Statement with @ Sign

Mike Schmitt — Tue, 30 Jul 2019 16:23:54 GMT

In case you or anyone else wants my code for this, here is the current version:

/*  Email Address Validation for Appian  */
  /*  Allows the 'name' to contain letters, numbers, plus period and special characters: _ - + ' & %  */
  /*  Allows the 'domain' to contain only letters, numbers, period and dash.  */

if(
  or(
    isnull(trim(ri!address)),
    len(trim(ri!address)) > 255,
    length(split(trim(ri!address), " ")) > 1,
    count(split(ri!address, "@")) <> 2
  ),
  false(),
  
  with(
    local!userPart: split(trim(ri!address),"@")[1],
    local!domainPart: split(trim(ri!address),"@")[2],
    
    if(
      or(
        length(split(local!domainPart, ".")) < 2,
        contains(split(local!userPart, "."), ""),
        contains(split(local!domainPart, "."), ""),
        not(isnull(stripwith(lower(local!domainPart), "abcdefghijklmnopqrstuvwxyz1234567890-."))),
        not(isnull(stripwith(lower(local!userPart), "abcdefghijklmnopqrstuvwxyz1234567890-._+'&%")))
      ),
        
      false(),
      true()
    )
  )
)

Saved as an Expression Rule, this code simply returns True or False, referring to whether a given email address is valid.

RE: If Not Statement with @ Sign

benjamins0003 — Tue, 30 Jul 2019 16:15:09 GMT

Thank you, Mike, that's very nice of you, I will consider it

RE: If Not Statement with @ Sign

benjamins0003 — Tue, 30 Jul 2019 16:14:49 GMT

Hello! This works very well. I have one other question. How may I change this code to accommodate a message? For ex: "Please Use '@'"? Thanks

RE: If Not Statement with @ Sign

Mike Schmitt — Mon, 29 Jul 2019 14:45:06 GMT

If you'd like a validation to make sure a user enters a syntactically-correct full email address, I have an expression rule that uses only out-of-box features that works rather well which i've posted here in the past, and would be willing to look up and repost for you if needed.

RE: If Not Statement with @ Sign

davel001150 — Mon, 29 Jul 2019 13:52:22 GMT

not(

like( ri!emailAddress, "*@*")

)

See how this works