custom picker

RE: custom picker

Max — Thu, 25 Feb 2021 16:56:11 GMT

Hello, good morning, I'm sorry. I occupy the same thing that you can't stay. What did you modify? your answer would help me a lot

RE: custom picker

Mike Schmitt — Tue, 19 Jan 2021 14:20:33 GMT

cool, thanks for confirming/verifying.

RE: custom picker

pradeepb0001 — Tue, 19 Jan 2021 07:50:33 GMT

i made some modification to your code and it worked perfectly.Thank you very much.

RE: custom picker

pradeepb0001 — Tue, 19 Jan 2021 05:26:35 GMT

Thank you Mike Schmitt for your reply,will work on your suggestion.

RE: custom picker

Mike Schmitt — Mon, 18 Jan 2021 15:36:00 GMT

As a followup: you would also be able to make the search work for "any country ID that contains the character '1'", however you would need a special column in your view, in which you cast the country ID to VARCHAR (text) instead of integer, as appian queries are unable to do an "includes" style query on integers. I just did this recently and it works like a charm.

For this scenario you should definitely use a view, and the text-cast column should be an *additional* column. As long as you've done that, then you would replace the "countryId" component of the filter set with the following, which is actually slightly more simple:

a!queryFilter(
  field: "countryIdText",
  operator: "includes",
  value: fv!item,
  /* applyWhen: not(rule!PROJECT_RULE_isBlank(tointeger(fv!item))) */
),

RE: custom picker

Mike Schmitt — Mon, 18 Jan 2021 15:31:55 GMT

The following suggest function would do what you're asking for - matching either on exact country id or on country name. As a bonus, a user would be able to type multiple parts of a country's name separated by a space and get results that have some match for all typed parts. Thanks to the flexibility of the a!queryLogicalExpression() construct (with the ability to nest and loop to basically any extent you could possibly want), we have a lot of flexibility with what search results are achievable, this being just one of a multitude of different possibilities.

a!localVariables(

  local!searchTextParts: a!forEach(
    split(ri!searchText, " "),
    if(rule!PROJECT_RULE_isBlank(fv!item), {}, fv!item)
  ),

  local!query: a!queryEntity(
    entity: cons!PROJECT_ENTITY_VIEW_COUNTRY_PICKER, /* DSE constant pointing to your countries table or view */
    query: a!query(
      logicalExpression: a!queryLogicalExpression(
        operator: "AND",
        filters: {
          a!queryFilter(
            field: "countryId", 
            operator: "not null"
          )
        },
        logicalExpressions: {
          a!queryLogicalExpression(
            operator: "AND",
            logicalExpressions: a!forEach(
              local!searchTextParts,
              
              a!queryLogicalExpression(
                operator: "OR",
                filters: {
                  a!queryFilter(
                    field: "countryId",
                    operator: "=",
                    value: fv!item,
                    applyWhen: not(rule!PROJECT_RULE_isBlank(tointeger(fv!item)))
                  ),
                  a!queryFilter(
                    field: "countryName",
                    /* OPERATOR can be either "starts with" or "includes" depending on your preference and/or project requirements */
                    operator: "includes",
                    value: tostring(fv!item)
                  )
                }
              )
            )
          )
        }
      ),
      pagingInfo: a!pagingInfo(
        startIndex: 1,
        batchSize: 20,
        sort: a!sortInfo(
          field: "countryId",
          ascending: true()
        )
      )
    )
  ),

  a!dataSubset(
    data: a!forEach(
      local!query.data,
      rule!PROJECT_Format_countryPickerLabel(country: fv!item) /* this rule would accept the Country CDT and return a single line of text representing how the Country name (and other details if desired) will appear in suggestion results as well as in the selected items list in the parent rule */
    ),
    identifiers: property(local!query.data, "countryId", {})
  )
)

RE: custom picker

pradeepb0001 — Mon, 18 Jan 2021 15:17:29 GMT

Thank you for your reply.If possible can you please provide any example for suggestion function?

RE: custom picker

Selvakumar Kumarasamy — Mon, 18 Jan 2021 14:33:15 GMT

Hi pradeepb0001,

If my understanding of your question is correct, then the answer would be yes. We can configure the custom picker to search based on different field data(such as name and code) and we can configure this in the suggestion function rule. But however, only one data subset can be returned as an output from the suggestion function & can be used inside the picker.