RE: Null Check Validation Failing

Stefan Helzle — Tue, 22 Jun 2021 08:00:09 GMT

This is a very common problem. In your case, length returns 1 because there is a single item, the NULL, in there.

In general I suggest to do all the data validation in the web API before initiating the process. If some of the fields are mandatory, then check for the individual fields.

To check whether a variable contains "something" I created an expression over the years. It covers 23 cases of "that variable is empty".

The rule input must be of type "any"!

if(
  isnull(ri!value),
  true,
  a!localVariables(
    local!typeNum: runtimetypeof(ri!value),
    
    /* Strings */
    if(
      local!typeNum = 'type!{http://www.appian.com/ae/types/2009}Text',
      /* Ignore white space */
      len(trim(ri!value)) = 0,
      
    /* List of Variant */
    if(
      local!typeNum = 'type!{http://www.appian.com/ae/types/2009}Variant?list',
      all(fn!isnull, a!flatten(ri!value)),
      
    /* Lists */
    if(
      /* Try to take first item in list and cast it to a list of itself */
      /* then compare its datatype to the incoming data type */
      local!typeNum = runtimetypeof(cast(runtimetypeof({index(ri!value, 1, null)}), ri!value)),
      
      /* Flatten takes care of lists in lists in lists in ... */
      /* List has zero non-null items, length() already ignores null values*/
      length(a!flatten(ri!value)) = 0,

    /* DataSubsets */
    if(
      local!typeNum = 'type!{http://www.appian.com/ae/types/2009}DataSubset',
      if(
        ri!value.totalCount < 0, /* This is necessary in case fetchTotalCount=false */
        if(
          isnull(ri!value.data),
          true,
          length(ri!value.data) = 0
        ),
        ri!value.totalCount = 0
      ),

      /* No idea what this could be so it is considered to not be null */
      false
    ))))
  )
)