want to convert "indiaChinaFrance" to "India China France"

RE: want to convert "indiaChinaFrance" to "India China France"

Acacio Barrado — Wed, 03 Nov 2021 06:15:30 GMT

Sorry I'm late in the party but also want to contribute.

I like your idea to use regex Selva. That is my idea:

a!localVariables(
  local!a: "indiaChinaFrance",
  local!b: regexinsertmatchmarkers("([A-Z])", local!a, " ", null, false(), "g"),
  local!b
)

Acacio B.

RE: want to convert "indiaChinaFrance" to "India China France"

Richard Michaelis — Mon, 01 Nov 2021 18:18:51 GMT

As I feel the community pressure here:
my shot:

a!localVariables(
  local!countryString: "indiaChinaFrance",
  local!brackets: append(
    a!forEach(
    items: enumerate(len(local!countryString))+1,
      expression: a!localVariables(
        local!charUnicode: code(charat(local!countryString,fv!index)),
        if(
          and(
            local!charUnicode=<90,
            local!charUnicode>=65
          ),
          fv!item,
          {}
        )
      )
    ),
    len(local!countryString)
  ),
  a!forEach(
    items: local!brackets,
    expression: if(
      fv!isFirst,
      concat(upper(charat(local!countryString,1)),mid(local!countryString,2,fv!item-2)),
      if(
        fv!isLast,
        mid(local!countryString,local!brackets[fv!index-1],fv!item+1-local!brackets[fv!index-1]),
        mid(local!countryString,local!brackets[fv!index-1],fv!item-local!brackets[fv!index-1])
      )
    )
  )
)

okaaaay its not really easier than stefans 😃

RE: want to convert "indiaChinaFrance" to "India China France"

Mike Schmitt — Mon, 01 Nov 2021 17:06:04 GMT

index(
  index(
    index(
      reduce(
        merge(
          apply(
            index(
              if(
                merge(
                  merge(
                    ...

*shudder*

RE: want to convert "indiaChinaFrance" to "India China France"

Chris — Mon, 01 Nov 2021 15:38:59 GMT

#JobSecurity 😆

It is a beautiful piece of code though! Not sure I even knew the proper() function existed until now..

Might as well include my solution here also 🙂

a!localVariables(
  local!input: "indiaChinaFrance",
  joinarray(
    a!forEach(
      items: enumerate(len(local!input)),
      expression: a!localVariables(
        local!char: charat(local!input,fv!index),
        if(
          fv!isFirst,
          upper(local!char),
          if(
            code(local!char)<97,
            concat(" ",local!char),
            local!char
          )
        )
      )
    )
  )
)

RE: want to convert "indiaChinaFrance" to "India China France"

Richard Michaelis — Sun, 31 Oct 2021 11:18:27 GMT

Stefaaaaaan 😂 I am not mike, but I remember during our last call I mentioned the factor of maintainability regarding coding :D
perhaps that is the most elegant way of all the above, but absolutly hell for people who shall maintain that. "reduce" in combination of merge and on top (multiple) "_" is definitly not inituive to read.... 😀

RE: want to convert "indiaChinaFrance" to "India China France"

Stefan Helzle — Sat, 30 Oct 2021 10:47:21 GMT

Could not hold me back. My looping function solution.I am sure Mike will love it ;-)

a!localVariables(
  local!input: "indiaChinaFrance",
  proper(
    reduce(
      substitute(_, _, _),
      local!input,
      merge(
        char(65+enumerate(26)),
        apply(concat(" ", _), char(65+enumerate(26)))
      )
    )
  )
)

RE: want to convert "indiaChinaFrance" to "India China France"

Selvakumar Kumarasamy — Fri, 29 Oct 2021 15:07:53 GMT

I thought of using regex & here's my solution:

a!localVariables(
  local!newString: regexreplaceall(
    "([A-Z]+)*([A-Z][a-z])",
    ri!string,
    "$1 $2"
  ),
  replace(
    local!newString,
    1,
    1,
    upper(left(local!newString, 1))
  )
)

RE: want to convert "indiaChinaFrance" to "India China France"

Mike Schmitt — Fri, 29 Oct 2021 14:57:17 GMT

yeah i agree, in a more complete implementation the if() logic should check that the current character is in the range of uppercase alphabetical letters, whereas in my quick-fix approach i just made checked that the current character's ascii code is lower than the lowest lowercase (since the ascii codes for uppercase characters are lower than the ones for lowercase, for anyone unfamiliar).

Attached is the less lazy way:

a!localVariables(
  /*local!lowerCaseA: code("a"),*/
  local!upperCaseA: code("A"),
  local!upperCaseZ: code("Z"),
  
  local!inputString: "indiaChinaFrance",
  
  local!codeArray: code(local!inputString),
  
  local!modifiedString: concat(a!forEach(
    local!codeArray,
    if(
      and(
        fv!item >= local!upperCaseA,
        fv!item <= local!upperCaseZ
      ),
      " " & char(fv!item),
      if(
        fv!isFirst,
        upper(char(fv!item)),
        char(fv!item)
      )
    )
  )),
  
  local!modifiedString
)

RE: want to convert "indiaChinaFrance" to "India China France"

Hemant Borate — Fri, 29 Oct 2021 14:52:43 GMT

Thank Mike Schmitt It's working

RE: want to convert "indiaChinaFrance" to "India China France"

Stewart Burchell — Fri, 29 Oct 2021 14:33:23 GMT

Yup, I think this is a more robust solution than mine...although if you ONLY want the delimiters to be Capital Letters then you'd need to exclude all those characters who have letters < A

RE: want to convert "indiaChinaFrance" to "India China France"

Mike Schmitt — Fri, 29 Oct 2021 14:31:09 GMT

a!localVariables(
  local!lowerCaseA: code("a"),
  
  local!inputString: "indiaChinaFrance",
  
  local!codeArray: code(local!inputString),
  
  local!modifiedString: concat(a!forEach(
    local!codeArray,
    if(
      fv!item < local!lowerCaseA,
      " " & char(fv!item),
      if(
        fv!isFirst,
        upper(char(fv!item)),
        char(fv!item)
      )
    )
  )),
  
  local!modifiedString
)

RE: want to convert "indiaChinaFrance" to "India China France"

Mike Schmitt — Fri, 29 Oct 2021 14:15:22 GMT

Assuming we'll always (and only) split on uppercase characters versus lowercase characters, this seems like a good place to (ab)use code() and char() conversions...

RE: want to convert "indiaChinaFrance" to "India China France"

Hemant Borate — Fri, 29 Oct 2021 13:32:59 GMT

@Stewart let me try

RE: want to convert "indiaChinaFrance" to "India China France"

Stewart Burchell — Fri, 29 Oct 2021 13:13:00 GMT

I'm sure there are easier ways (awaits others to gleefully provide simpler solutions) but here's my offering:

a!localVariables(
  local!items: { "A", "B", "C", "D", "E", "F" },
  local!splitAttribute: fn!reduce(fn!split, ri!attributeName, local!items),
  a!forEach(
    items: local!splitAttribute,
    expression: if(
      fv!isFirst,
      fn!proper(fv!item),
      fn!concat(
        ri!attributeName[fn!find(fv!item, ri!attributeName, 1) - 1],
        fv!item
      )
    )
  )
)

The idea is to have the full set of characters that you want to use as delimiters in the string you want to process (I've only provide A-F as an example).

You then split the incoming string based upon that list. Unfortunately (j this instance) the split function excludes the value you're splitting, so you up wiht a list where the first item is whole but the remaining items are missing their first character.

The aim of the remainder of the code is to re-append the missing character to each item in the list generated by the split processing.