Images display based on total no of Id's

RE: Images display based on total no of Id's

gaddamv0001 — Thu, 09 Dec 2021 11:38:02 GMT

Yeah , This is the basic structure .thank you ajhick. I will try an change it according to my requirements. Thank you

RE: Images display based on total no of Id's

ajhick — Thu, 09 Dec 2021 11:30:40 GMT

This is the basic bones. I've stopped it displaying past two rows but haven't included any code to scroll through the pages, I'll leave that up to you. Play around with the local!numberOfListingsToGenerate, local!maxListingsPerRow and local!maxRowsPerPage variables to see the different results you get.

If the second row is uneven I haven't done anything about that but you'd have to consider how you'd want to do this and could be quite tricky for some numbers of listings.

Is this the sort of thing you're after?

a!localVariables(
  local!numberOfListingsToGenerate: 9,
  local!listings: a!forEach(
    items: 1 + enumerate(local!numberOfListingsToGenerate),
    expression: a!map(
      address: concat(
        fv!index,
        " Test St, Testville"
      )
    )
  ),
  local!numberOfListings: if(
    a!isNullOrEmpty(local!listings),
    0,
    length(local!listings)
  ),
  local!maxListingsPerRow: 5,
  local!maxRowsPerPage: 2,
  local!numberOfColumns: min(
    local!numberOfListings,
    local!maxListingsPerRow
  ),
  local!totalRows: roundup(
    local!numberOfListings / local!maxListingsPerRow,
    0
  ),
  local!numberOfRows: min(
    local!totalRows,
    local!maxRowsPerPage
  ),
  a!columnsLayout(
    columns: {
      a!forEach(
        items: 1 + enumerate(local!numberOfColumns),
        expression: a!localVariables(
          local!columnNumber: fv!item,
          a!columnLayout(
            contents: {
              a!forEach(
                items: 1 + enumerate(local!numberOfRows),
                expression: a!localVariables(
                  local!index: product(fv!item - 1, local!numberOfColumns) + local!columnNumber,
                  local!listing: index(
                    local!listings,
                    local!index,
                    {}
                  ),
                  local!address: index(
                    local!listing,
                    "address",
                    {}
                  ),
                  a!cardLayout(
                    contents: {
                      a!richTextDisplayField(
                        labelPosition: "COLLAPSED",
                        value: {
                          a!richTextIcon(
                            icon: "home",
                            size: "LARGE_PLUS"
                          ),
                          a!richTextItem(
                            text: concat(
                              char(10),
                              char(10),
                              char(10),
                              local!address
                            ),
                            style: {
                              "STRONG",
                              "UNDERLINE"
                            }
                          )
                        },
                        align: "CENTER"
                      )
                    },
                    height: "MEDIUM",
                    style: "NONE",
                    marginBelow: "STANDARD",
                    showWhen: not(a!isNullOrEmpty(local!listing))
                  )
                )
              )
            }
          )
        )
      )
    }
  )
)

RE: Images display based on total no of Id's

gaddamv0001 — Thu, 09 Dec 2021 11:13:12 GMT

yeah

RE: Images display based on total no of Id's

ajhick — Thu, 09 Dec 2021 11:12:57 GMT

So a max of 2 rows per page?

RE: Images display based on total no of Id's

gaddamv0001 — Thu, 09 Dec 2021 11:12:13 GMT

Yeah i want to display the listings and its details in a card layout and i wanted limited no of listings per row

That is 5 per row and 10 per page

RE: Images display based on total no of Id's

ajhick — Thu, 09 Dec 2021 11:10:34 GMT

I'm not sure I fully understand what you're trying to achieve. Is it that you want to display all your listings in card layouts in a dynamic fashion where no matter the number of listings it just keeps listing them? Do you want to have a maximum number of listings per row? It seems like 3?