How to generate base64 digest string in Appian.

RE: How to generate base64 digest string in Appian.

varshau — Tue, 24 Mar 2026 09:04:24 GMT

Thanks Mike this worked.

RE: How to generate base64 digest string in Appian.

lalithap4822 — Tue, 21 Jan 2025 13:07:36 GMT

Thanks Mike. This worked.

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Mon, 20 Jan 2025 15:43:28 GMT

After some further research, I found that extended characters (anything past char(127)) are handled specially in standard UTF-8 base64 encoding. I did a little tampering with my existing rules and came up with the following updates today:

Encoder:

/* encode */
a!localVariables(
  local!text: ri!text,

  local!charset: "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/",
  local!codeArray: code(local!text),
  local!binArray: a!forEach(
    local!codeArray,
    if(
      fv!item > 127,
      if(
        fv!item > 2047,
        if(
          fv!item > 65535,
          dec2bin(fv!item, 21),
          dec2bin(fv!item, 16)
        ),
        dec2bin(fv!item, 11)
      ),
      dec2bin(fv!item, 8)
    )
  ),
  
  local!preProcessBinArray: a!forEach(
    /* encoding UTF-8 self-synchronizing (grumble) ref: https://en.wikipedia.org/wiki/UTF-8#Description */
    items: local!binArray,
    expression: a!match(
      value: len(fv!item), default: fv!item,
      
      equals: 8,
      then: fv!item,
      
      equals: 11,
      then: {
        concat( "110", left(fv!item, 5) ),
        concat( "10", right(fv!item, 6) )
      },
      
      equals: 16,
      then: {
        concat( "1110", left(fv!item, 4) ),
        concat( "10", mid(fv!item, 5, 6) ),
        concat( "10", right(fv!item, 6) )
      },
      
      equals: 21,
      then: {
        concat( "11110", left(fv!item, 3) ),
        concat( "10", mid(fv!item, 4, 6) ),
        concat( "10", mid(fv!item, 10, 6) ),
        concat( "10", right(fv!item, 6) )
      }
    )
  ),
  
  local!bins: concat(local!preProcessBinArray),
  
  local!groupedBins: split(concat(
    a!forEach(
      items: code(local!bins), 
      expression: char(fv!item) & if(and(mod(fv!index, 6) = 0, not(fv!isLast)), "-=-=-", "")
    )
  ), "-=-=-" ),
  local!lastBin: index(local!groupedBins, length(local!groupedBins)),
  local!padding: a!match(
    value: len(local!lastBin),
    equals: 2, then: "==",
    equals: 4, then: "=",
    equals: 6, then: "",
    default: "error condition"
  ),
  local!bindexes: a!forEach(
    items: local!groupedBins,
    expression: if(
      fv!isLast,
      bin2dec(substitute(padright(fv!item, 6), " ", "0")),
      bin2dec(fv!item)
    )
  ) + 1,

  local!assembledOutput: concat(a!forEach(items: local!bindexes, expression: charat(local!charset, fv!item))) & local!padding,

  local!assembledOutput
)

Decoder:

/* decode */
a!localVariables(
  local!base64text: ri!base64text,

  local!charset: "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/",

  local!charCodes: code(local!base64text),
  /*local!paddingCount: count(wherecontains(code("="), local!charCodes)),*/
  local!unpaddedChars: a!flatten(a!forEach(
    items: local!charCodes,
    expression: if(fv!item = code("="), {}, find(char(fv!item), local!charset)-1)
  )),
  local!rawBins: dec2bin(tointeger(local!unpaddedChars), 6),

  local!decodedBins: split(
    concat(
      a!forEach(
        items: code(concat(local!rawBins)),
        expression: if(
          mod(fv!index, 8) = 0,
          char(fv!item) & "-=-=-",
          char(fv!item)
        )
      )
    ),
    "-=-=-"
  ),

  
  local!intermediaryDecodedBinList: a!flatten(a!forEach(
    /* update to handle UTF-8 self-synchronizing for extended character-set items. ref: https://en.wikipedia.org/wiki/UTF-8#Description */
    items: local!decodedBins,
    expression: if(
      or(fv!item = "0000", fv!item = "00"),
      {},
      
      a!match(
        value: fv!item, default: fv!value,

        /* handle 2-byte items */
        whentrue: left(fv!value, 3) = "110",
        then: concat(right(fv!item, 5), right(local!decodedBins[fv!index+1], 6)),
        whenTrue: or(  /* manually check and skip re-using subsequent ones on following iterations (ugh) */
          and(fv!index >= 2, left(local!decodedBins[fv!index-1], 3) = "110"),
        ),
        then: {},

        /* handle 3-byte items */
        whentrue: left(fv!value, 4) = "1110",
        then: concat(right(fv!item, 4), right(local!decodedBins[fv!index+1], 6), right(local!decodedBins[fv!index+2], 6)),
        whenTrue: or(  /* manually check and skip re-using subsequent ones on following iterations (ugh) */
          and(fv!index >= 2, left(local!decodedBins[fv!index-1], 4) = "1110"),
          and(fv!index >= 3, left(local!decodedBins[fv!index-2], 4) = "1110")
        ),
        then: {},

        /* handle 4-byte items */
        whentrue: left(fv!value, 5) = "11110",
        then: concat(right(fv!item, 3), right(local!decodedBins[fv!index+1], 6), right(local!decodedBins[fv!index+2], 6), right(local!decodedBins[fv!index+3], 6)),
        whenTrue: or(  /* manually check and skip re-using subsequent ones on following iterations (ugh) */
          and(fv!index >= 2, left(local!decodedBins[fv!index-1], 5) = "11110"),
          and(fv!index >= 3, left(local!decodedBins[fv!index-2], 5) = "11110"),
          and(fv!index >= 4, left(local!decodedBins[fv!index-3], 5) = "11110")
        ),
        then: {}
        
      )
    )
  )),
  
  concat(
    a!forEach(
      local!intermediaryDecodedBinList,
      char(bin2dec(fv!item))
    )
  )
)

These work with text containing the euro symbol and other extended character set items to an extent. Warning that I have *not* tested them very thoroughly for corner cases (like items that exist at character set boundaries) yet, but the results so far match results given by public online base64 encoder tools.

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Mon, 20 Jan 2025 15:31:36 GMT

[quote userid="245102" url="~/discussions/f/integrations/23810/how-to-generate-base64-digest-string-in-appian/144487"]failing to decode Euro symbol[/quote]

Are you talking about the "â" character? Because that's what it looks like your example string contains. I'm unclear but for some reason my base64 back-parser is interpreting it as 2 characters instead of 1, which I'll look into - it could be an error in my parser, or some weird exception involving the convergence of character sets or something, i'm not terribly sure yet.

RE: How to generate base64 digest string in Appian.

lalithap4822 — Fri, 17 Jan 2025 23:09:43 GMT

Hi Mike,

I tried your code and it is failing to decode Euro symbol. Here is the same from my encoded text "U2ltaWxhYyBBZHZhbmNlIMOiIFIwMzUxMjNQ". Unfortunately, I can't use decodebase64string() as it has size limitation to 2000 characters.

RE: How to generate base64 digest string in Appian.

lalithap4822 — Fri, 17 Jan 2025 23:06:42 GMT

Hello Mike,

I tried your code & it isn't decoding Euro symbol. Here is a sample from my encoded text - "U2ltaWxhYyBBZHZhbmNlIMOiIFIwMzUxMjNQ". Can you please check. Unfortunately, I can't use decodebase64string since it has a size limitation of 2000 characters.

RE: How to generate base64 digest string in Appian.

MK0001 — Mon, 08 Jul 2024 15:11:20 GMT

yes, done Verified

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Mon, 08 Jul 2024 15:09:21 GMT

Just out of curiosity, does that change if you click this first?

RE: How to generate base64 digest string in Appian.

MK0001 — Mon, 08 Jul 2024 14:51:42 GMT

Yes, I already tried verifying the answer but could not be able to do it. The reason may be because the owner of the conversation is different.

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Mon, 08 Jul 2024 14:49:32 GMT

great, thanks for confirming 🙂
(BTW if you want to "verify" my old answer(s) here that'd be great here too - i notice nobody else ever did, lol)

RE: How to generate base64 digest string in Appian.

MK0001 — Mon, 08 Jul 2024 14:48:34 GMT

Sorry Mike, Missed this one. Thank you soo much. This works.

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Mon, 08 Jul 2024 14:45:35 GMT

[quote userid="276052" url="~/discussions/f/integrations/23810/how-to-generate-base64-digest-string-in-appian/137746"]Yes, it is actually converting base64 to text, but I need to convert text to base 64. [/quote]

I have at least 2 different rules posted above. One converts base64 to text, and the other converts text to base64. Are you saying you've tried both of them? It seems to me like you've probably missed one.

RE: How to generate base64 digest string in Appian.

MK0001 — Mon, 08 Jul 2024 14:41:24 GMT

Yes, it is actually converting base64 to text, but I need to convert text to base 64. I tried using encodebase64string() function, but it is having some limitation of 150 characters. Could you please suggest me the other ways of converting text to base 64?

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Mon, 08 Jul 2024 14:32:26 GMT

[quote userid="276052" url="~/discussions/f/integrations/23810/how-to-generate-base64-digest-string-in-appian/137628"]I need to convert it into Base64 format. How can I achieve this?[/quote]

Did you try the expression rule(s) I pasted above? They're pretty straight-forward...

RE: How to generate base64 digest string in Appian.

MK0001 — Fri, 05 Jul 2024 10:41:28 GMT

Hi Mike Schmitt , Could you please help me in my requirement.
My input is in Text format, I need to convert it into Base64 format. How can I achieve this?

RE: How to generate base64 digest string in Appian.

Alexis Díaz Fajardo — Fri, 12 Apr 2024 17:56:59 GMT

I have not. Anyway, 10,000 characters sounds better than 1,600 right? :)

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Fri, 12 Apr 2024 13:42:36 GMT

[quote userid="266581" url="~/discussions/f/integrations/23810/how-to-generate-base64-digest-string-in-appian/133231"]character limit of 150[/quote]

yikes 😬

edit: have you tested this: a few comments there suggest the limit is actually more than 150 characters now (in spite of what they have published on the description page). I updated my version of the plug-in and it seems to take upwards of 1600 characters now (the old one did break at 152, instead of 150 oddly).

RE: How to generate base64 digest string in Appian.

Alexis Díaz Fajardo — Fri, 12 Apr 2024 06:03:16 GMT

Thats nice to hear. Im asking because the plugin Base64 Expressions have in its functions a character limit of 150.

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Thu, 11 Apr 2024 15:54:22 GMT

[quote userid="266581" url="~/discussions/f/integrations/23810/how-to-generate-base64-digest-string-in-appian/133194"]limits of characters [/quote]

Within reason. Do you have anything specific in mind?

To confirm - i just tested it on a 10,000 character randomly-generated Lorem Ipsum text, and it worked in less than 5 seconds. I guess I'd hesitate to call it on text much longer than this, just for performance concerns.

RE: How to generate base64 digest string in Appian.

Alexis Díaz Fajardo — Thu, 11 Apr 2024 15:50:32 GMT

Have you tested the limits of characters for this code?

RE: How to generate base64 digest string in Appian.

Abhay Dalsaniya — Thu, 04 Jan 2024 19:08:14 GMT

Great work!!!

RE: How to generate base64 digest string in Appian.

Jason — Thu, 04 Jan 2024 19:02:24 GMT

You sir, are my hero!

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Thu, 04 Jan 2024 18:58:07 GMT

[quote userid="6113" url="~/discussions/f/integrations/23810/how-to-generate-base64-digest-string-in-appian/123695"]do you happen to have a base64 decoder written as well?[/quote]

In fact, yes.

/* note: deprecated old version.  please see my updated version(s) down-thread, these now handle extended characters correctly. */

RE: How to generate base64 digest string in Appian.

Jason — Thu, 04 Jan 2024 18:30:35 GMT

Mike, do you happen to have a base64 decoder written as well? I'll try to reverse engineer your encoder in the meantime. Thanks!

RE: How to generate base64 digest string in Appian.

Mike Schmitt — Fri, 05 May 2023 15:09:57 GMT

[quote userid="115564" url="~/discussions/f/integrations/23810/how-to-generate-base64-digest-string-in-appian/112269#112269"]This code snippet, will help us to convert simple text to base64 ?[/quote]

Yes, the code I posted (which is custom code I wrote 100% from scratch on my own in Appian) should generate standard Base64 given an input string. I've tested the base64 it generates with external base64 convertors and at least thus far I haven't found any areas where it doesn't work correctly.