Trying to understand local/scoping of variables

RE: Trying to understand local/scoping of variables

MaNa — Sat, 11 Mar 2023 20:02:10 GMT

Abhay: That is what I learned from Stefan and you. I am used to using {} to segment code from C/C++ - Appian seems to have interpretations based on {} - didn't realize { indicated start of expression. Live and Learn.

I am going to post another problem - for nested forEach() - where not sure why the local variables are not working.

RE: Trying to understand local/scoping of variables

MaNa — Sat, 11 Mar 2023 19:58:43 GMT

Mike,

That sounds like an approach I should investigate - will do soon.

RE: Trying to understand local/scoping of variables

Abhay Dalsaniya — Fri, 10 Mar 2023 20:38:54 GMT

[quote userid="82813" url="~/discussions/f/new-to-appian/28040/trying-to-understand-local-scoping-of-variables/109158#109158"]As for the syntax in image 2, isn't the a!localVariable() on line 1, similar to the example in your response?[/quote]

No it is not. The {} start the expression part and you cannot define local variable in the expression part directly the way you did it. To do that you need to have another nested localvariable() function, as I mentioned in my previous response. Hope this helps!

RE: Trying to understand local/scoping of variables

Mike Schmitt — Fri, 10 Mar 2023 19:45:08 GMT

Yes, if the requirement is that your form should show GPA and that the only rows which appear are those where it's non-blank, then the key is to filter your data in advance of feeding it into your grid.

If you're querying the data from the DB, then you would simply provide a query filter and filter out rows where that value is not populated.

If, on the other hand, you are passing the whole data set (with a mixture of rows) like as a process PV array, then you could instead create an on-form temp variable consisting only of the rows you'd like to display. Something along the lines of, local!myTempArray: a!forEach(ri!myWholeArray, if(a!isNullOrEmpty(fv!item.GPA), {}, fv!item) within your local variables declaration. Then you'd simply pass that local variable into the data parameter of your grid, and you'd be displaying only the rows which have a value populated here.

RE: Trying to understand local/scoping of variables

Stefan Helzle — Fri, 10 Mar 2023 19:44:50 GMT

I support you idea of fetching only the required data instead of fetching all, wasting memory and trying to hide some of the data in the UI.

RE: Trying to understand local/scoping of variables

MaNa — Fri, 10 Mar 2023 19:40:09 GMT

Mike,

The use case is when multiple faculty members submit grades for a student and GPAs are calculated after all faculty members submit their grades. Until all grades are submitted, the GPA column is null. So, I didn't want the interface displaying any rows where GPA column is null.

Guess the right approach would be to filter the data (pass only rows where the GPA column is not NULL) but I was experimenting to explore if there was a way to provide users with an option to either view or not view a row based on a column value (e.g., show only students/GPAs that qualify for Deans' List).

RE: Trying to understand local/scoping of variables

Mike Schmitt — Fri, 10 Mar 2023 19:13:31 GMT

[quote userid="82813" url="~/discussions/f/new-to-appian/28040/trying-to-understand-local-scoping-of-variables/109176#109176"]that would allow me to hide an entire row if one or more columns have is empty/null[/quote]

You might want to think a bit more about this. Why would you want to hide a row when a column has an entirely empty/null value? What would this even look like / accomplish?

RE: Trying to understand local/scoping of variables

MaNa — Fri, 10 Mar 2023 15:56:49 GMT

I guess what I am looking for is something similar to 'disableRowSelectionWhen' that would allow me to hide an entire row if one or more columns have is empty/null.

RE: Trying to understand local/scoping of variables

Stefan Helzle — Fri, 10 Mar 2023 13:44:49 GMT

So, facts first. As per the documentation fv!row can ONLY be used when assigning to the value parameter.

https://docs.appian.com/suite/help/23.1/Grid_Column_Component.html#parameters

Now, about the why. It just does not make sense in any other parameter as the gridColumn component defines the logic for the whole column.

If you want to show/hide a component in an individual cell, just add a richttextdisplayfield and make it show data according to your logic.

RE: Trying to understand local/scoping of variables

MaNa — Fri, 10 Mar 2023 12:58:32 GMT

Stefan,

I can accept that Appian treats the curly-braces as the start of an expression. Back to my original issue, which is why is using "fv!row" (image below) causing a scoping variable issue. Isn't fv!row part of the gridField function that should be available at line:56? It is available at line 55. If passing it to the isNotNullorEmpty function is the issue, how do I access the value of fv!row in a function/expression for something like let's say to determine if the row is an odd or even row?

Thanks for your help.

RE: Trying to understand local/scoping of variables

Stefan Helzle — Fri, 10 Mar 2023 07:09:07 GMT

It is not the same. Because of the added curly brackets that local variable is never declared as Appian evaluates this as the expression part of a!localVariables.

RE: Trying to understand local/scoping of variables

MaNa — Thu, 09 Mar 2023 22:51:37 GMT

Abhay:

Thanks for helping me understand this concept. As for the syntax in image 2, isn't the a!localVariable() on line 1, similar to the example in your response?

Isn't the scope defined by a!localVariable valid for all statements between matching pairs of ()? So anything you defined after line 1 should be available throughout the rest of the code. Am I wrong in that interpretation ?

I was using this as the reference (https://docs.appian.com/suite/help/23.1/Local_Variables.html). In the example they have:

value: if(isnull(local!input), "No", "Yes"),

While I understand I am using "fv!row" not "local!input" as part of showWhen attribute (showWhen:a!isNotNullOrEmpty(fv!row.number)) , it gives me an error (image 1 in original post). I am trying to understand why/when I can use "fv!row" and why there is a scoping error.

a!columnsLayout(
  columns: {
    a!localVariables(
      local!input,
      {
        a!columnLayout(
          contents: {
            a!textField(
              label: "Input",
              value: local!input,
              saveInto: local!input
            )
          }
        ),
        a!columnLayout(
          contents: {
            a!textField(
              label: "Input Entered?",
              value: if(isnull(local!input), "No", "Yes"),
              readOnly: true
            )
          }
        )
      }
    )
  }
)

RE: Trying to understand local/scoping of variables

Abhay Dalsaniya — Thu, 09 Mar 2023 22:27:04 GMT

Ref. https://docs.appian.com/suite/help/23.1/fnc_evaluation_a_localvariables.html

RE: Trying to understand local/scoping of variables

Abhay Dalsaniya — Thu, 09 Mar 2023 22:24:14 GMT

Please try to understand the syntax of a!localVariables().

a!localVariables( localVar1, localVarN, expression )

In your image2, you have defined local!productsList without using localVariable() which is violating the syntax because it is the expression portion.

use something like following.

a!localVariables(
  {
    a!localVariables(
      local!productList: rule!abc(),
      a!gridField()
    )
  }
)

See the color coding to understand it better.

RE: Trying to understand local/scoping of variables

Abhay Dalsaniya — Thu, 09 Mar 2023 22:17:38 GMT

looks like fv!raw can only be used in the value parameter. Remove it from showWhen:a!isNotNullOrEmpty(fv!row.firstName)

Instead do following.

1. Define local variable (e.g. local!data) and capture the query result set into it.

2. Refer local!data into gridField -> data.

3. For showWhen condition Use local!data.firstName = <something>

RE: Trying to understand local/scoping of variables

MaNa — Thu, 09 Mar 2023 22:15:15 GMT

Abhay,

That was understanding - variable is available within the defined block. Unless, I am missing something, I don't see why line 8 in my example (second image in my original post) gives an error when the variable is defined on line 3. However, if I remove the braces on line 2 and 24, the error goes away (see image below).

Madhu

RE: Trying to understand local/scoping of variables

MaNa — Thu, 09 Mar 2023 22:06:33 GMT

Abhay,

Here is the code - emblem

a!localVariables(
  local!selection,
  local!selectedEmployees,
  local!showIneligible:true,
  {
    a!checkboxField(
      label: "Checkboxes",
      labelPosition: "COLLAPSED",
      choiceLabels: {"Show ineligible employees"},
      choiceValues: {true()},
      value: if(local!showIneligible, true(),null()),
      saveInto: a!save(
        local!showIneligible,
        if(
          isnull(save!value),
          false(),
          true()
        )
      ),
      validations: {}
    ),
  a!columnsLayout(
    columns: {
      a!columnLayout(
        contents: {
          a!gridField(
            label: "Employee Directory",
            labelPosition: "ABOVE",
            data: a!queryEntity(
              entity: cons!CR_EMPLOYEE_ENTY_CNST,
              query: a!query(
                selection: a!querySelection(
                  columns: {
                    a!queryColumn(
                      field: "id"
                    ),
                    a!queryColumn(
                      field: "firstName"
                    ),
                    a!queryColumn(
                      field: "lastName"
                    ),
                    a!queryColumn(
                      field: "department"
                    ),
                    a!queryColumn(
                      field: "startDate"
                    )
                  }
                ),
                logicalExpression: a!queryLogicalExpression(
                  operator: "AND",
                  filters: {
                    a!queryFilter(
                      field: "department",
                      operator: "<>",
                      value: "Sales",
                      applyWhen: not(local!showIneligible)
                    )
                  },
                  ignoreFiltersWithEmptyValues: true
                ),
                pagingInfo: fv!pagingInfo
              ),
              fetchTotalCount: true
            ),
            columns: {
              a!gridColumn(
                label: "First Name",
                sortField: "firstName",
                value: fv!row.firstName,
                showWhen:a!isNotNullOrEmpty(fv!row.firstName)
              ),
              a!gridColumn(
                label: "Last Name",
                sortField: "lastName",
                value: fv!row.lastName
                /*showWhen:a!isNotNullOrEmpty(fv!row.lastName)*/
              ),
              a!gridColumn(
                label: "Department",
                sortField: "department",
                value: a!richTextDisplayField(
                  value: {
                    a!richTextItem(
                      text: {fv!row.department},
                      color: if(fv!row.department="Sales","SECONDARY",null),
                      style: {
                        "EMPHASIS"
                      }
                    )
                  }
                )
              ),
              a!gridColumn(
                label: "Start Date",
                sortField: "startDate",
                value: if(
                isnull(fv!row.startDate),
                fv!row.startDate,
                datetext(fv!row.startDate, "default")
                ),
                align: "END"
              ),
              a!gridColumn(
                label: "Id",
                sortField: "id",
                value: fv!row.id,
                align: "END"
              )
            },
            initialSorts: {
              a!sortInfo(
                field: "lastName",
                ascending: true
              )
            },
            selectable: true,
            selectionValue: local!selection,
            selectionSaveInto: {
              local!selection,

              /* This save adds the full rows of data for items selected in the most recent user interaction to local!selectedEmployees. */
              a!save(local!selectedEmployees, append(local!selectedEmployees,fv!selectedRows)),
              /* This save removes the full rows of data for items deselected in the most recent user interaction to local!selectedEmployees */
              a!save(local!selectedEmployees, difference(local!selectedEmployees,fv!deselectedRows))
            },
            disableRowSelectionWhen: fv!row.department="Sales",
            validations: {}
          )
        },
        width: "WIDE"
      ),
      a!columnLayout(
        contents: {
          a!richTextDisplayField(
            label: "Selected Employees",
            labelPosition: "ABOVE",
            value: a!forEach(
              items:local!selectedEmployees,
              expression: {
                a!richTextIcon(
                  icon:"user-circle"
                ),
                " " & fv!item.firstName & " " & fv!item.lastName & char(10)
              }
            )
          )
        }
      )
    }
  )
}
)

RE: Trying to understand local/scoping of variables

Abhay Dalsaniya — Thu, 09 Mar 2023 22:01:41 GMT

It's simple. The variable is accessible within the block into which it is defined.

See the following to understand it better -

a!localVariables(
  local!a: 1,
  {
    a!localVariables(local!b: 2, local!a),
    local!b
  }
)

RE: Trying to understand local/scoping of variables

Abhay Dalsaniya — Thu, 09 Mar 2023 21:54:01 GMT

Can you post your code using following instead of the image.