How to Auto Increment Alpha Characters in an expression rule to create sequential ID's

RE: How to Auto Increment Alpha Characters in an expression rule to create sequential ID's

harshav — Thu, 25 May 2017 06:46:43 GMT

Thanks for all the answers. They work great.

RE: How to Auto Increment Alpha Characters in an expression rule to create sequential ID's

jasonf — Wed, 24 May 2017 19:18:56 GMT

Thanks to immense help from Jackie, here's the set of rules that seem to work for this as best as I've tested so far. (In case anyone else ever needs it)

ri!allowedLetters is a passed in constant with a text array of letters allowed to be used for incrementation
ri!inputString is the original alpha string passed in

load(
  
  local!newString: null,
  
  local!arrayWithString:
    rule!GBL_incrementAlphaString(
      allowedLetters: ri!allowedLetters,
      inputString: ri!inputString,
      newString: local!newString
    ),
    
  local!updatedString:
    index(
      local!arrayWithString,
      count(local!arrayWithString), null
    ),
    
  local!updatedString
)

GBL_incrementAlphaString

  reduce(
    rule!GBL_alphaStringIncrementer(
      newString:_,
      position:_,
      allowedLetters: ri!allowedLetters,
      inputString: ri!inputString
    ),
    {},
    reverse(enumerate(len(ri!inputString))+1)
  )

GBL_alphaStringIncrementer

with(
  local!letter: index(ri!inputString, ri!position, null),
  local!index: wherecontains(local!letter, ri!allowedLetters),
  local!nextLetter: 
    if(
      or(
        rule!APN_isBlank(ri!inputString),
        local!index = count(ri!allowedLetters)
      ),
      index(ri!allowedLetters, 1, null),
      index(ri!allowedLetters, local!index+1, null)
    ),

  local!indexLowerLetter: 
    index(ri!allowedLetters,
      wherecontains(index(ri!newString, ri!position+1, null), ri!allowedLetters),
      null 
    ),
    
  local!lastPositionChangedFromZ: 
    toboolean(index(ri!newString, count(ri!newString)-1, null)),
  {
    local!index = count(ri!allowedLetters),
    
    if(
      ri!position = len(ri!inputString),
    
      replace(ri!inputString, ri!position, 1, local!nextLetter),
      
      
      if(
        local!lastPositionChangedFromZ,
        replace(index(ri!newString, count(ri!newString), null), ri!position, 1, local!nextLetter),
        ri!newString
      )
    )
  }
)

RE: How to Auto Increment Alpha Characters in an expression rule to create sequential ID's

Jackie Jubien — Tue, 23 May 2017 19:04:01 GMT

This allows you to make this an extremely dynamic rule - by using reduce()

load(
reduce(
rule!jcj_testingAlphaIncrementer(

newId:_,
position:_,
allowedLetters: ri!allowedLetters,
lastIdAlpha:ri!lastIdAlpha
),
{},
reverse(enumerate(len(ri!lastIdAlpha))+1)
)
)

with(
local!letter: index(ri!lastIdAlpha, ri!position, null),
local!index: wherecontains(local!letter, ri!allowedLetters),
local!nextLetter:
if(
or(
rule!APN_isBlank(ri!lastIdAlpha),
local!index = count(ri!allowedLetters)
),
index(ri!allowedLetters, 1, null),
index(ri!allowedLetters, local!index+1, null)
),
local!indexLowerLetter:
index(ri!allowedLetters,
wherecontains(index(ri!newId, ri!position+1, null), ri!allowedLetters),
null
),

if(ri!position = count(ri!allowedLetters),

replace(ri!lastIdAlpha, ri!position, 1, local!nextLetter),

if(
local!indexLowerLetter = "A",
replace(ri!newId, ri!position, 1, local!nextLetter),
ri!newId
)
)
)

RE: How to Auto Increment Alpha Characters in an expression rule to create sequential ID's

jasonf — Tue, 23 May 2017 17:20:02 GMT

Thank you I will play with this. I intend to have a rule input for how many characters are being passed in, and whether or not bytes can be added once all Z's are reached or not and if so how many etc. Thanks for the response.

RE: How to Auto Increment Alpha Characters in an expression rule to create sequential ID's

Mike Schmitt — Tue, 23 May 2017 16:57:20 GMT

I'm sure this can be done more gracefully if you utilize looping, but the following expression works as far as I can tell (though you'd want to add failsafes for the case where fewer than 4 characters get passed in):

with(
  
  local!codes: code(ri!input),
  local!A: 65,
  local!Z: 90,
  
  local!4thChar: if(local!codes[4] = local!Z, local!A, local!codes[4]+1),
  local!4thCharCarry: if(local!codes[4] = local!Z, 1, 0),
  
  local!3rdChar: if(local!codes[3]+local!4thCharCarry > local!Z, local!A, local!codes[3]+local!4thCharCarry),
  local!3rdCharCarry: if(local!codes[3]+local!4thCharCarry > local!Z, 1, 0),
  
  local!2ndChar: if(local!codes[2]+local!3rdCharCarry > local!Z, local!A, local!codes[2]+local!3rdCharCarry),
  local!2ndCharCarry: if(local!codes[2]+local!3rdCharCarry > local!Z, 1, 0),
  
  local!1stChar: if(local!codes[1]+local!2ndCharCarry > local!Z, local!A, local!codes[1]+local!2ndCharCarry),
  
  concat(char({ local!1stChar, local!2ndChar, local!3rdChar, local!4thChar }))
  
)