find duplicate characters count in a string

RE: find duplicate characters count in a string

varshithak774792 — Mon, 14 Oct 2024 05:26:14 GMT

a!localVariables(
local!string : "appian training",
local!chars : char(code(stripwith(local!string," "))),
local!uniquechars : union(local!chars,local!chars),
local!count : a!forEach(
items: local!uniquechars,
expression: a!map(
item : fv!item,
count : length(wherecontains(fv!item,local!chars))
)
),
local!output : a!forEach(
items: local!count,
expression: fv!item.item&"-------------"&fv!item.count,
),
local!output
)

RE: find duplicate characters count in a string

Stefan Helzle — Sat, 12 Oct 2024 19:10:47 GMT

a!localVariables(
  local!word: "Banana",
  local!chars: char(code(local!word)),
  a!forEach(
    items: union(local!chars, local!chars),
    expression: concat(
      cleanwith(local!word, fv!item),
      "-------",
      len(cleanwith(local!word, fv!item))
    )
  )
)

RE: find duplicate characters count in a string

Akshat Lakhera — Sat, 12 Oct 2024 18:26:32 GMT

a!localVariables(
  local!code: code("Banana"),
  local!distinctCode: union(local!code, local!code),
  a!forEach(
    local!distinctCode,
    a!localVariables(
      local!charCount: length(wherecontains(fv!item, local!code)),
      concat(
        repeat(local!charCount, char(fv!item)),
        "-------",
        local!charCount
      )
    )
  )
)

RE: find duplicate characters count in a string

ankitd679341 — Wed, 09 Oct 2024 12:33:46 GMT

a!localVariables(
local!name: "ankit dahiya",
local!letters: a!forEach(code(local!name), char(fv!item)),
local!uniqueLetters: union(local!letters, local!letters),
touniformstring(
a!forEach(
items: remove(
local!uniqueLetters,
wherecontains(" ", local!uniqueLetters)
),
expression: {
fv!item & "-" & count(wherecontains(fv!item, local!letters))
}
)
)
)

RE: find duplicate characters count in a string

shukurs0001 — Fri, 26 Aug 2022 15:30:03 GMT

a!localVariables(
local!input: "SHUKUR",
local!array1: char(code(local!input)),
local!array: union(local!array1,local!array1),
a!forEach(
items: local!array,
expression: a!localVariables(
local!count: if(
regexmatch(fv!item,local!input)>0,
count(regexallmatches(fv!item,local!input)),
{}
),
concat(repeat(local!count,fv!item),"--------",local!count)
)
)
)

RE: find duplicate characters count in a string

Mike Schmitt — Mon, 25 Apr 2022 14:23:37 GMT

Thanks!

RE: find duplicate characters count in a string

Bejjenki_Rajender — Mon, 25 Apr 2022 14:22:41 GMT

this is simple way and easy ..thank you @Mike Schmitt

RE: find duplicate characters count in a string

Mike Schmitt — Mon, 25 Apr 2022 14:12:35 GMT

Here's a somewhat different implementation - slightly longer but more focused on abstracting the individual steps on easier-to-understand local variable definitions, and without a need to iterate over an array of all 26 letters.

a!localVariables(
  
  local!word: "banana",
  
  local!letters: a!forEach(
    code(lower(local!word)),
    char(fv!item)
  ),
  
  local!uniqueLetters: union(local!letters, local!letters),
  
  local!counts: a!forEach(
    local!uniqueLetters,
    a!map(
      letter: fv!item,
      count: length(wherecontains(fv!item, local!letters))
    )
  ),
  
  a!forEach(
    local!counts,    
    concat(repeat(fv!item.count, fv!item.letter)) & " ----> " & fv!item.count
  )
)

RE: find duplicate characters count in a string

Bejjenki_Rajender — Mon, 25 Apr 2022 12:40:25 GMT

nice.

RE: find duplicate characters count in a string

Naresh — Mon, 25 Apr 2022 12:14:48 GMT

Hi,

Another way to achieve this logic

a!localVariables(
  local!word: "Banana",
  a!forEach(
    items: {
      "A","B","C","D","E","F","G","H", "I","J","K","L",
      "M","N","O","P","Q","R","S","T","U","V","W","X","Y","Z"
    },
    expression: a!localVariables(
      local!count: if(
        regexmatch(fv!item, upper(local!word), 1) > 0,
        count(regexallmatches(fv!item,local!word)),
        {}
      ),
      if(
        a!isNullOrEmpty(local!count),
        {},
        concat(repeat(local!count, fv!item), "-------", local!count)
      )
    )
  )
)