RE: File Extension

Mike Schmitt — Fri, 21 Oct 2022 22:24:31 GMT

I just use a pair of helper expression rules to get the document name from the ID (as it returns a whole name in a plaintext blob of info, we need to extract it from the output)

a!localVariables(
  local!rawDetails: if(
    a!isNullOrEmpty(ri!doc),
    "",
    getcontentobjectdetailsbyid(ri!doc)
  ),
  local!wholeName: index(extract(
    local!rawDetails,
    "[Name: ",
    ", UUID:"
  ), 1, null()),

  rule!UTIL_processDocumentName(
    docName: local!wholeName
  )
)

That in turn calls UTIL_processDocumentName (which can be fed a "whole filename" from any source and for any reason) and uses Regex to help prevent weird corner-cases:

a!localVariables(
  local!hasNoExtension: search(".", ri!docName) = 0,
  
  local!namePart: if(
    local!hasNoExtension,
    ri!docName,
    regexsearch(
      pattern: ".*(?=\.)",
      searchString: ri!docName,
      regexFlags: "i"
    )[1].match
  ),
  
  local!extension: if(
    local!hasNoExtension,
    "",
    regexsearch(
      pattern: "[^\.]*$",
      searchString: ri!docName,
      regexFlags: "i"
    )[1].match
  ),
  
  a!map(
    name: local!namePart,
    extension: local!extension
  )
)