To find the greatest number in the array without max function

RE: To find the greatest number in the array without max function

Mathieu Drouin — Sun, 14 Jan 2024 14:16:56 GMT

A couple of suggestions:

You can simply set the batchSize to 1 in the pagingConfiguration. With this you can reduce the number of times you use the index function.
You can simply cast to an integer rather than getting the first element of the array, this removes another index.

a!localVariables(
  local!list: { 67, 80, 100, 102, 150 },
  local!map: a!forEach(
    items: local!list,
    expression: a!map(number: fv!item)
  ),
  local!dataSubset: todatasubset(
    arrayToPage: local!map,
    pagingConfiguration: a!pagingInfo(
      startIndex: 1,
      batchSize: 1,
      sort: a!sortInfo(field: "number", ascending: false)
    )
  ),
  cast(
    typeof(1),
    index(local!dataSubset.data, "number", null)
  )
)

RE: To find the greatest number in the array without max function

Harshit Bumb (Appyzie) — Sun, 14 Jan 2024 12:54:36 GMT

sort is actually an undocumented function. This neither comes up as a suggestion nor there is any documentation page for the same.
I won't advise using it.

RE: To find the greatest number in the array without max function

Sri Ram Kaja — Sun, 14 Jan 2024 12:40:43 GMT

Hi romeoraja ,

Below one might be helpful.

a!localVariables(
  local!list: { 67, 80, 100, 102, 150 },
  local!map: a!forEach(
    items: local!list,
    expression: a!map(number: fv!item)
  ),
  index(
    index(
      index(
        todatasubset(
          arrayToPage: local!map,
          pagingConfiguration: a!pagingInfo(
            startIndex: 1,
            batchSize: length(local!list),
            sort: a!sortInfo(field: "number", ascending: false)
          )
        ),
        "data",
        {}
      ),
      "number",
      {}
    ),
    1,
    {}
  )
)

RE: To find the greatest number in the array without max function

Amaan Shekh — Fri, 05 Jan 2024 17:14:11 GMT

I was going with a different approach with local variables and forgot to remove a!localVariables() when I moved to rule inputs😅.

RE: To find the greatest number in the array without max function

Mike Schmitt — Fri, 05 Jan 2024 15:49:40 GMT

I'd point out that you're not actually declaring any local variable in this rule, and thus it's unnecessary to even call a!localVariables() other than potentially if you want to add one in the future for easier understanding.

RE: To find the greatest number in the array without max function

Amaan Shekh — Fri, 05 Jan 2024 06:21:14 GMT

Here is an O(n) approach implemented like C, employing a temporary variable to store the current maximum (rule input ). In this implementation, a recursive approach has been utilized. If you have any questions or need further clarification, feel free to ask.

  if(
    ri!currentIndex > length(ri!arr),
    ri!currentMax,
    rule!maxNum(
      arr: ri!arr,
      currentMax: if(
        ri!currentMax > ri!arr[ri!currentIndex],
        ri!currentMax,
        ri!arr[ri!currentIndex]
      ),
      currentIndex: ri!currentIndex + 1
    )
  )


/*arr: array in which we needs to find max num*/
/*currentMax: first element of array*/
/*current index: first index of array (1 in case of appian)*/

result->

RE: To find the greatest number in the array without max function

kraty Maheshwari — Mon, 01 Jan 2024 09:18:45 GMT

This might be helpful.

a!localVariables(
  local!listOfNumber: { 67, 80, 100, 102, 150 },
  a!forEach(
    items: local!listOfNumber,
    expression: a!localVariables(
      local!item: fv!item,
      local!updatedList: remove(local!listOfNumber, fv!index),
      if(
        count(
          wherecontains(
            true,
            a!forEach(
              items: local!updatedList,
              expression: local!item > fv!item
            )
          )
        ) = count(local!updatedList),
        fv!item,
        {}
      )
    )
  )
)

RE: To find the greatest number in the array without max function

Alex Boerescu — Fri, 30 Dec 2022 10:33:45 GMT

Or use the sort function:

a!localVariables(
  local!list:{5,4,7,9,2,5,0},
  sort(local!list)[length(local!list)]
)

RE: To find the greatest number in the array without max function

prasadp — Thu, 29 Dec 2022 12:28:18 GMT

reduce(
  rule!getMaxNumber(accumulator: _, item: _),
  0,
  ri!array
)

We can use reduce function

Create a rule which will compare the current item and accumulator and return the max number and use that rule as predicate in reduce fucntion

RE: To find the greatest number in the array without max function

romeoraja — Thu, 29 Dec 2022 08:15:44 GMT

was practicing to do same as in c , using a local temp variable

RE: To find the greatest number in the array without max function

Harshit Bumb (Appyzie) — Thu, 29 Dec 2022 06:41:25 GMT

Why do you want to do it without the max() function when you can use it?