Josephus Problem

RE: Josephus Problem

Nikhil Chandra Reddy Tetali — Fri, 11 Aug 2023 05:33:56 GMT

Here is the solution to your challenge. We have also added a feather so that the user may choose the number of players and who should start the game.

reduce(
  rule!EI_subEliminateTask(list: _, value: _),
  {
    ldrop(
      enumerate(ri!players) + 1,
      ri!startPlayer - 1
    ),
    if(
      ri!startPlayer = 1,
      {},
      enumerate(ri!startPlayer - 1) + 1
    )
  },
  repeat(ri!players - 1, 0)
)

subrule: rule!EI_subEliminateTask(list: _, value: _),
code: { ldrop(ri!list, 2), ri!list[1] }

RE: Kill in the circle

jamesm4933 — Thu, 10 Aug 2023 18:06:01 GMT

It's called the Josephus Problem. It was inspired by a story in "The Jewish War" by Flavius Josephus.

Apparently, the solutions for n=2 up to group size 78 are sequence number A006257 in the On-line Encyclopedia of Integer Sequences

Wikipedia

The Jewish War

RE: Kill in the circle

Chris — Thu, 10 Aug 2023 16:13:45 GMT

Yes this is the code for the rule. Being recursive, it calls itself 😉

Optimized a bit:

if(
  count(ri!list)<=1,
  index(ri!list,1,null),
  a!localVariables(
    local!removeIndex: if(ri!index=count(ri!list),1,
    if(ri!index>count(ri!list),2,ri!index+1)
    ),
    rule!chris_test_kc_recur(
      list: remove(ri!list,local!removeIndex),
      index: local!removeIndex
    )
  )
)

RE: Kill in the circle

Mike Schmitt — Thu, 10 Aug 2023 14:27:17 GMT

[quote userid="213297" url="~/discussions/f/rules/29603/kill-in-the-circle/117502#117502"]please share me the code rule!chris_test_kc_recur[/quote]

lol, he did say this is a recursive rule...

RE: Kill in the circle

Richard Michaelis — Thu, 10 Aug 2023 06:55:08 GMT

why not trying yourself than getting it served already prepared? :) The question was , if it was possible. yes it is. :)

RE: Kill in the circle

afzalk0001 — Thu, 10 Aug 2023 04:32:37 GMT

can you please share me the code rule!chris_test_kc_recur? That would be helpful

RE: Kill in the circle

Chris — Wed, 09 Aug 2023 15:41:06 GMT

This is my example with a recursive rule to solve the puzzle (#73).

As always, make sure to save recursive rules before testing.

/* rule!chris_test_kc_recur(
      list (Number Array, 1+enumerate(100))
      index (Number, 1)
   )
*/

if(
  count(ri!list)<=1,
  index(ri!list,1,null),
  a!localVariables(
    local!removeIndex: if(
      ri!index=count(ri!list),
      1,
      if(
        ri!index>count(ri!list),
        2,
        ri!index+1
      )
    ),
    local!list: remove(ri!list,local!removeIndex),
    rule!chris_test_kc_recur(
      list: local!list,
      index: local!removeIndex
    )
  )
)

RE: Kill in the circle

Stefan Helzle — Wed, 09 Aug 2023 11:55:37 GMT

As Appian follows a functional approach, you cannot modify variables during runtime. You line 14 will not work.

Make this recursive, or use the reduce() function. It allows you to modify data across iterations.

appian.rocks/.../

RE: Kill in the circle

afzalk0001 — Wed, 09 Aug 2023 11:49:24 GMT

Yeah its a puzzle problem. You can refer this - https://www.geeksforgeeks.org/puzzle-100-people-in-a-circle-with-gun-puzzle/

i was just trying to implement using appian.

RE: Kill in the circle

Mathieu Drouin — Wed, 09 Aug 2023 11:46:09 GMT

Is this some sort of exam question?

RE: Kill in the circle

afzalk0001 — Wed, 09 Aug 2023 11:40:52 GMT

a!localVariables(
  local!makeArray: a!forEach(
    items: enumerate(ri!number) + 1,
    expression: fv!item
  ),
  local!resultArray,
  local!position: 1,
  a!forEach(
      items: local!makeArray,
      expression:
      {
        local!position+1,
        mod(local!position,length(fv!item)),
        remove(local!resultArray,local!position)
      }       
   )
)

I tried this code but not able to get the possible solution. If you find any possible please help me with this. Thanks in advance

RE: Kill in the circle

Richard Michaelis — Wed, 09 Aug 2023 11:35:49 GMT

sure it is ;)
looping functions might be your friend :)
a!forEach is one of them
https://docs.appian.com/suite/help/23.2/fnc_looping_a_foreach.html

RE: Kill in the circle

Stefan Helzle — Wed, 09 Aug 2023 11:35:42 GMT

You can implement recursive and iterative algorithms. So, the answer is: Yes!

RE: Kill in the circle

afzalk0001 — Wed, 09 Aug 2023 11:16:26 GMT

No just wanted to try using appian. Whether is it possible using expressuin rules or not?

RE: Kill in the circle

Richard Michaelis — Wed, 09 Aug 2023 11:14:54 GMT

Thats no appian related question, is it ;)?