I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

NicolasY — Fri, 07 Jun 2019 09:49:10 GMT

Trie this 100%sure this will wok for you

union(intersection(ri!array1,ri!array2),intersection(ri!array1,ri!array2))

greetings

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

Josh — Fri, 05 Apr 2019 19:56:24 GMT

See you in 18 months for another thread revival.

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

Mike Schmitt — Fri, 05 Apr 2019 19:54:20 GMT

fair enough - though if anyone is concerned with using sort() as in my example, they may simply replace this with their own expression rule that sorts via officially supported functionality, i.e. passing an array through toDataSubset with a sorting parameter added.

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

davel001150 — Fri, 05 Apr 2019 19:33:11 GMT

Yes he does specify unique.

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

Josh — Fri, 05 Apr 2019 19:31:38 GMT

It is not correct based on the example provided in the original question. I'm glad it helped you out, though.

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

davel001150 — Fri, 05 Apr 2019 19:29:06 GMT

It's correct from a certain perspective. This preserves the number of times an item has been duplicated. It's actually exactly what I was looking for.

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

davel001150 — Fri, 05 Apr 2019 19:14:13 GMT

I do apologize, but for the sake of others I have to call out my alarm at a suggested answer which features the undocumented sort() function. (I don't understand why such a thing wouldn't be documented, but there you go)

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

Mike Schmitt — Fri, 06 Apr 2018 15:28:17 GMT

Not that this thread isn't already ancient, but since it's been brought back up, I'll post the updated version of my old function that gets duplicate array members (now we have a!forEach and don't require sub-functions).

Note: this funciton returns ALL duplicate members, i.e. any and all array members that have a duplicate anywhere else in the array. If the need is for a list where each duplicate member appears only once, this result can be further de-duplicated.

with(
  local!uniqueMembers: rule!GLBL_removeDuplicateArrayMembers(
    array: ri!array
  ),  /* note: this funciton does "union(ri!array, ri!array)". it's useful to have as a global function. */
  
  local!indicesIfMultiple: a!forEach(
    items: local!uniqueMembers,
    expression: with(
      local!indices: wherecontains(
        fv!item,
        ri!array
      ),
      if(
        rule!APN_arrayLength(local!indices) > 1,
        local!indices,
        {}
      )
    )
  ),
  
  index(
    ri!array,
    sort(local!indicesIfMultiple),
    {}
  )
)

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

Josh — Fri, 06 Apr 2018 14:28:33 GMT

This is an incorrect solution. It will break for the following case: {1,2,3,4,4,5,5,5,3}. Instead of returning {3,4,5}, it returns {3,4,5,5}.

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

Thenmozhi Mohanakrishnan — Fri, 06 Apr 2018 14:17:24 GMT

load(
local!a: {1,2,3,4,4,5,3},
remove(local!a,a!forEach(
items: union(local!a,local!a),
expression: wherecontains(fv!item,local!a)[1]
))
)

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

Mike Schmitt — Wed, 08 Apr 2015 00:13:00 GMT

I'll throw in the solution I implemented for my project, which will take an Any Type array and return just the duplicates:

function: getArrayDuplicates()
rule input: ri!array (Any Type)

with(
uniques: union(ri!array, ri!array),
singlesIndex: if(length(ri!array) = length(uniques),
{},
apply(rule!whereContainsSingle, uniques, ri!array)
),

if(length(ri!array) = length(uniques),
{},
remove(
ri!array,
singlesIndex
)
)
)

sub function: whereContainsSingle()
ri!values (any type)
ri!array (any type)

with(
indices: wherecontains(ri!values, ri!array),
if(length(indices) > 1, {}, indices)
)

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

darbyk — Tue, 07 Apr 2015 22:21:36 GMT

Hi Fariaj, if I understand your use case, you want to find and return the duplicate items in your array (e.g. findDuplicates({1,2,3,4,4,5,3, 3}) will return {3,4}. This is a quick way to do it I believe (keep in mind you'll probably need some null checks):

TEST_isDuplicate:
=length(wherecontains(ri!value, ri!array)) > 1

Then the actual rule - TEST_findDuplicates:
=with(
local!input: {1,2,3,4,4,5,3},
local!uniqueInputs: union(local!input, local!input),
filter(rule!TEST_isDuplicate(_, local!input), local!uniqueInputs)
)

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

PhilB — Tue, 07 Apr 2015 19:23:07 GMT

I would suggest doing it this way:

load(
local!array: {1,2,3,4,4,5,3},
union(local!array,local!array)
)

You can also use rule!APN_distinct in place of the union() function if you have the common objects installed. If you want to know how many duplicate items there are, just do something like this:

load(
local!array: {1,2,3,4,4,5,3},
length(
local!array
) - length(
union(
local!array,
local!array
)
)
)

RE: I have an Array {1,2,3,4,4,5,3} . I want to know how many duplicate values are t

best — Tue, 07 Apr 2015 17:57:19 GMT

Use
union({1,2,3,4,4,5,3},tointeger({}))