How to create a todatasubset with Column values have array of elements?

RE: How to create a todatasubset with Column values have array of elements?

ramp — Tue, 08 May 2018 05:41:32 GMT

This solves my use case

RE: How to create a todatasubset with Column values have array of elements?

ramp — Tue, 08 May 2018 05:41:01 GMT

Thanks for the working solution. here is the little updated version by enabling the selection to get the selected row indexes.

load(
local!custArray: touniformstring( "aaa", "bbb", "ccc" ),
local!prodNmArray: { "ddd", "eee", "ggg" },
local!qtyArray: { 10, null, 30 },
local!priceArray: { 40, 50, 60 },
local!array: a!forEach(
    items: local!custArray,
    expression: {
      customerName: index(local!custArray, fv!index, null),
      productName: index(local!prodNmArray, fv!index, null),
      quantity: index(local!qtyArray, fv!index, null),
      price: index(local!priceArray, fv!index, null)
    }
),
local!gridSelection:a!gridSelection(
    pagingInfo: a!pagingInfo(
    startIndex: 1,
    batchSize: 10
)
),
local!finalData: todatasubset(
    local!array,
    topaginginfo( 1, - 1 )
),
a!formLayout(
    label: "Test Data" & local!gridSelection.selected,
    contents: {
      a!gridField(
        label: "Test",
        totalCount: local!finalData.totalCount,
        columns: {
          a!gridTextColumn(
            label: "Customer",
            data: index( local!finalData.data, "customerName", null )
          ),
          a!gridTextColumn(
            label: "Product Name",
            data: index( local!finalData.data, "productName", null )
          ),
          a!gridTextColumn(
            label: "Quantity",
            data: index( local!finalData.data, "quantity", null )
          ),
          a!gridTextColumn(
            label: "Price",
            data: index( local!finalData.data, "price", null )
          )
        },
        value: local!gridSelection,
        saveInto: a!save(target:local!gridSelection,value:save!value),
        identifiers: local!finalData.identifiers,
        selection: true
      )
    }
)
)

Thanks a lot. its solved my requirements

RE: How to create a todatasubset with Column values have array of elements?

Brazil Vibanco — Mon, 07 May 2018 11:58:03 GMT

Adding some little changes:

load(
  local!custArray: touniformstring( "aaa", "bbb", "ccc" ),
  local!prodNmArray: { "ddd", "eee", "ggg" },
  local!qtyArray: { 10, null, 30 },
  local!priceArray: { 40, 50, 60 },
  local!array: a!forEach(
    items: local!custArray,
    expression: {
      customerName: index(local!custArray, fv!index, null),
      productName: index(local!prodNmArray, fv!index, null),
      quantity: index(local!qtyArray, fv!index, null),
      price: index(local!priceArray, fv!index, null)
    }
  ),
  local!finalData: todatasubset(
    local!array,
    topaginginfo( 1, - 1 )
  ),
  a!formLayout(
    label: "Test Data",
    contents: {
      a!gridField(
        label: "Test",
        totalCount: local!finalData.totalCount,
        columns: {
          a!gridTextColumn(
            label: "Customer",
            data: index( local!finalData.data, "customerName", null )
          ),
          a!gridTextColumn(
            label: "Product Name",
            data: index( local!finalData.data, "productName", null )
          ),
          a!gridTextColumn(
            label: "Quantity",
            data: index( local!finalData.data, "quantity", null )
          ),
          a!gridTextColumn(
            label: "Price",
            data: index( local!finalData.data, "price", null )
          )
        },
        value: a!pagingInfo( 1, - 1 )
      )
    }
  )
)

Hope it solves your issue

RE: How to create a todatasubset with Column values have array of elements?

krishnaprasadd — Mon, 07 May 2018 08:35:04 GMT

Hi megharanib,

I tried with the same Example and it is working for me without using the cast function. If you Still facing the issue just provide some sample data to me so that it will be helpful for me to find out the issue.

Please find the Sample Code below:

load(
local!custArray: {
"aaa",
"bbb",
"ccc"
},
local!prodNmArray: {
"ddd",
"eee",
"ggg"
},
local!qtyArray: {
10,
20,
30
},
local!priceArray: {
40,
50,
60
},
local!array: apply(
rule!POC_genericTestRule(
customerName: _,
productName: _,
quantity: _,
price: _
),
merge(
local!custArray,
local!prodNmArray,
local!qtyArray,
local!priceArray
)
),
local!finalData: todatasubset(
local!array,
topaginginfo(
1,
- 1
)
),
a!formLayout(
label: "Test Data",
firstColumnContents: {
a!gridField(
label: "Test",
totalCount: local!finalData.totalCount,
columns: {
a!gridTextColumn(
label: "Customer",
data: index(
local!finalData.data,
"customerName",
""
)
),
a!gridTextColumn(
label: "Product Name",
data: index(
local!finalData.data,
"productName",
""
)
),
a!gridTextColumn(
label: "Quantity",
data: index(
local!finalData.data,
"quantity",
""
)
),
a!gridTextColumn(
label: "Price",
data: index(
local!finalData.data,
"price",
""
)
)
},
value: a!pagingInfo(
1,
- 1
)
)
}
)
)

POC_genericTestRule:

{
customerName: ri!customerName,
productName: ri!productName,
quantity: ri!quantity,
price: ri!price
}

RE: How to create a todatasubset with Column values have array of elements?

ramp — Mon, 07 May 2018 07:13:14 GMT

Can you provide the working sample please

RE: How to create a todatasubset with Column values have array of elements?

krishnaprasadd — Mon, 07 May 2018 06:25:15 GMT

Hi megharanib,

I tried with the same code and it is working in my case. I think the data what you created is of type "List of Variant". Convert into dictionary before forming the datasubset using cast(194, data). Then you will get the desired totalcount.

I hope this will work

RE: How to create a todatasubset with Column values have array of elements?

ramp — Mon, 07 May 2018 05:50:20 GMT

Hi,
More or less I am expecting the same. but when I am trying to render to paging grid its not happening. todatasubset(local!array,topaginginfo(1,-1)).totalCount resulting only one row.

we need to render this todatasubsset into paging grid. help me how to achieve this.

Thanks for prompt response.

RE: How to create a todatasubset with Column values have array of elements?

megharanib — Mon, 07 May 2018 05:26:45 GMT

load(
local!custArray:{"aaa","bbb","ccc"},
local!prodNmArray:{"ddd","eee","ggg"},
local!qtyArray:{10,20,30},
local!priceArray:{40,50,60},
local!array:merge(local!custArray,local!prodNmArray,local!qtyArray,local!priceArray),
todatasubset(local!array,topaginginfo(1,-1))
)

If i am not wrong, this is what you are expecting.