Checkbox False Value Not being saved

RE: Checkbox False Value Not being saved

Mike Schmitt — Wed, 05 Feb 2020 13:18:33 GMT

I see you had a working solution suggested already, but I figured I would chip in with my experience in case it helps you or anyone else.

So, the basic fact here is that a!checkboxField() wasn't really made to handle a simple boolean (yes/no) selection at all. It can be done but it requires a bit of legwork.

To deal with this, a few years ago I went ahead and created a "boolean checkbox" interface to serve as a shortcut - the extra legwork is handled internally so that when it's called, you only need to pass in some specific things to get it working:

trueValue: the value you want saved into your target variable when the box is checked
falseValue: the value it should get when the box is un-checked (note: this can be anything, but it will require the user to check and un-check the box to get this value)
value: this is the primary save target, as well as the source of what the checkbox should display (i.e. whether it will appear checked or unchecked). Initially it should be equal to the value of either trueValue or falseValue (or null). If set to anything other than these choices, the checkbox will also appear unchecked.
checkboxLabel -or- label: i typically leave "label" blank and set "checkboxLabel" to a value which then appears to the right of the checkbox

/* GLBL_Component_BooleanCheckbox */
a!checkboxField(
  label: ri!label,
  choiceLabels: { ri!checkboxLabel },
  choiceValues: { ri!trueValue },
  value: if(
    ri!value = ri!trueValue,
    ri!value,
    null()
  ),
  saveInto: {
    a!save(
      ri!value,
      if(isnull(save!value), ri!falseValue, ri!trueValue)
    )
  },
  
  /* optional standard parameters: */
  labelPosition: ri!labelPosition,
  instructions: ri!instructions,
  helpTooltip: ri!helpTooltip,
  required: ri!required,
  requiredMessage: ri!requiredMessage,
  accessibilityText: ri!accessibilityText,
  disabled: ri!readOnly,
  validations: ri!validations,
  align: ri!align,
  showWhen: ri!showWhen
)

All the other rule inputs are optional, and just allow the component to act more like the regular checkboxField when desired (labelPosition, instructions, validations, etc.)

RE: Checkbox False Value Not being saved

robertab0001 — Tue, 04 Feb 2020 22:25:40 GMT

It worked!

Should I remove the if condition from the saveInto attribute in the checkbox component?

Thank you so much!

Roberta

RE: Checkbox False Value Not being saved

Karina Vazquez — Tue, 04 Feb 2020 22:16:51 GMT

Oh, I understand, try changing the save in the buttonWidget with a if in the value:
a!save(
ri!requests.requirements,
if(
isnull(local!reqdoc),
false,
true
)
)

RE: Checkbox False Value Not being saved

robertab0001 — Tue, 04 Feb 2020 22:11:41 GMT

Thanks, Karina Vazquez.

I would like to have one checkbox instead of two (yes/no) and not a radio button at all. The reason is because the user will have to select other checkboxes within my form. Each option is a Boolean value in my database.

I don't want to save value as null but true or false as a Boolean value.

Roberta

RE: Checkbox False Value Not being saved

Karina Vazquez — Tue, 04 Feb 2020 21:58:47 GMT

Hi Roberta,

The reason is because only exists the value true in your check box, (choiceValues: {true},) if you want to save a true/false I recommended you to use a radio button

a!radioButtonField(
label: "Requirements documentation",
labelPosition: "ABOVE",
choiceLabels: {"true","false"},
choiceValues: {true,false},
value: if(local!reqdoc, true, null),
saveInto: a!save(local!reqdoc, if(isnull(save!value), false, true))
)

or change de save to allow to save a null value,

a!checkboxField(
label: "",
labelPosition: "ABOVE",
choiceLabels: {"Requirements documentation"},
choiceValues: {true},
value: if(local!reqdoc, true, null),
saveInto: a!save(local!reqdoc, if(isnull(save!value), null, true))
),

I hope the information is helpful

Regards