RE: How to add validation to an inline grid addRowLink?

varunkumarb0001 — Mon, 10 Feb 2020 13:31:01 GMT

lol. Even I came up with the same solution. Thanks for confirming...

RE: How to add validation to an inline grid addRowLink?

Mike Schmitt — Mon, 10 Feb 2020 13:25:16 GMT

The simplest way to do this is just remove the Add Row Link when you have reached the maximum number of grid elements. The Add Row Link itself doesn't have a validation configuration. You could add validation on the Grid itself, but assuming you set up the Add Row link properly, there should be no way by which the validation condition could ever become true.

Quick example:

a!localVariables(
  
  local!gridContents: {
    {
      id: 1,
      name: "asdf"
    }
  },
  
  a!sectionLayout(
    label: "Test Grid",
    contents: {
      a!gridLayout(
        headerCells: {
          a!gridLayoutHeaderCell(label: "Id"),
          a!gridLayoutHeaderCell(label: "Name")
        },
        columnConfigs: {
          a!gridLayoutColumnConfig(width: "NARROW")
        },
        rows: a!forEach(
          local!gridContents,
          a!gridRowLayout(
            contents: {
              a!textField(
                value: fv!item.id,
                readOnly: true()
              ),
              a!textField(
                value: fv!item.name,
                saveInto: fv!item.name
              )
            }
          )
        ),
        addRowLink: a!dynamicLink(
          label: "Add Row",
          /* in older versions of Appian, using a showWhen here would result in an error condition, 
            so it was necessary to wrap the whole dynamicLink in an if() statement.  This seems to 
            now be fixed (as of Appian 19.4) */
          showWhen: length(local!gridContents) < 6,
          saveInto: {
            a!save(
              local!gridContents,
              append(local!gridContents, {id: null(), name: null()})
            )
          }
        )
      )
    }
  )
)