Count of Characters in Paragraph field

RE: Count of Characters in Paragraph field

Chris — Wed, 19 May 2021 16:12:30 GMT

Until the upgrade, I can only suggest utilizing the validation parameters on both the paragraph fields and on the grid itself - this will show hover over on the paragraph field as well as line by line errors underneath the grid. Additionally, you could add a skinny column next to the paragraph field for a length display - but as the others have noted here, this is probably about the best you can do until you upgrade.

a!localVariables(
  local!data: {
    {field1: ""},
    {field1: ""}
  },
  local!maxLength: 500,
  a!gridLayout(
    label: "Grid",
    headerCells: {
      a!gridLayoutHeaderCell(label: "Field 1"),
      a!gridLayoutHeaderCell(label: "Validation")
    },
    rows: a!forEach(
      items: local!data,
      expression: a!gridRowLayout(
        id: fv!index,
        contents: {
          a!paragraphField(
            value: fv!item.field1,
            saveInto: local!data[fv!index].field1,
            required: true,
            validations: {
              if(
                len(local!data[fv!index].field1)>local!maxLength,
                concat("Please enter less than ",local!maxLength," characters.  Current length: ",len(local!data[fv!index].field1)),
                null
              )
            }
          ),
          a!richTextDisplayField(
            value: {
              a!richTextItem(
                text: concat("Length ",len(fv!item.field1),"/",local!maxLength),
                style: "EMPHASIS",
                color: "SECONDARY"
              )
            }
          )
        }
      )
    ),
    validations: {
      reject(
        fn!isnull,
        a!forEach(
          items: local!data,
          expression: {
            if(
              len(fv!item.field1)>local!maxLength,
              concat("Please enter less than ",local!maxLength," characters in line ",fv!index,".  Current length: ",len(fv!item.field1)),
              null
            )
          }
        )
      )
    },
    addRowLink: a!dynamicLink(
      label: "Add a Row",
      saveInto: a!save(local!data,append(local!data,{field1: null}))
    )
  )
)

RE: Count of Characters in Paragraph field

Mike Schmitt — Wed, 19 May 2021 15:34:39 GMT

Ok then - this new feature was released in 21.1, so you'll be able to enable this to show up inherently directly in the paragraph field as soon as you can upgrade. Until then I'm not sure there's all that much you can do.

RE: Count of Characters in Paragraph field

vineethk0001 — Wed, 19 May 2021 14:57:14 GMT

its an 20.4

RE: Count of Characters in Paragraph field

Mike Schmitt — Wed, 19 May 2021 14:33:40 GMT

Agreed with Stefan - what version of Appian are you on currently?

RE: Count of Characters in Paragraph field

Stefan Helzle — Wed, 19 May 2021 14:01:18 GMT

Appian 21.1 includes this OOTB.

RE: Count of Characters in Paragraph field

GauravSingh — Wed, 19 May 2021 12:54:20 GMT

Either you can give some additional field in the right side to show the count but that's not at all recommended.

Other thing you can try is give one text field on top or bottom in readOnly format just to display the length of paragraph you are currently working with...here you will need one extra local variable to store the length of the filed and that you will use as value in the text field

RE: Count of Characters in Paragraph field

vineethk0001 — Wed, 19 May 2021 12:25:13 GMT

Thank you Gaurav, is there any way i can achieve showing the count of characters

RE: Count of Characters in Paragraph field

GauravSingh — Wed, 19 May 2021 12:00:31 GMT

For Grid you cannot show instruction

RE: Count of Characters in Paragraph field

GauravSingh — Wed, 19 May 2021 11:57:07 GMT

Sharing this sample code it will help you

a!localVariables(
local!para,
a!paragraphField(
value: local!para,
saveInto: {
local!para,
},
height: "SHORT",
instructions: "Number of characters " & len(local!para) & "/500",
refreshAfter: "KEYPRESS",
validations: if(
len(local!para) <= 500,
"",
"500 characters maximum."
)
)
)