RE: Select countries based on Regions

Harshit Bumb (Appyzie) — Mon, 19 Sep 2022 10:11:24 GMT

I have updated the code. Let me know if it works.

RE: Select countries based on Regions

Shubham Kumar — Mon, 19 Sep 2022 09:49:58 GMT

Hi Harshit,

Thanks for your quick reply!

User can select multiple regions at a time, and countries belongs to regions must be auto selected in countries dropdwon list

RE: Select countries based on Regions

Harshit Bumb (Appyzie) — Mon, 19 Sep 2022 09:34:36 GMT

This code snippet should help

a!localVariables(
  local!regions: {
    { id: 1, name: "Region 1",  },
    { id: 2, name: "Region 2",  },
    { id: 3, name: "Region 3",  }
  },
  local!countries: {
    { id: 1, name: "Country 1", regionId: 1 },
    { id: 2, name: "Country 2", regionId: 1 },
    { id: 3, name: "Country 3", regionId: 1 },
    { id: 4, name: "Country 4", regionId: 2 },
    { id: 5, name: "Country 5", regionId: 2 },
    { id: 6, name: "Country 6", regionId: 2 }
  },
  local!selectedRegion,
  local!selectedCountries,
  {
    a!multipleDropdownField(
      label: "Region",
      choiceLabels: local!regions.name,
      choiceValues: local!regions.id,
      value: local!selectedRegion,
      saveInto: {
        local!selectedRegion,
        a!save(
          local!selectedCountries,
          a!flatten(
            index(
              local!countries.id,
              wherecontains(
                tointeger(local!selectedRegion),
                tointeger(local!countries.regionId)
              ),
              {}
            )
          )
        )
      },
      placeholder: "---Country---"
    ),
    a!multipleDropdownField(
      label: "Country",
      choiceLabels: a!flatten(
        index(
          local!countries.name,
          wherecontains(
            tointeger(local!selectedRegion),
            tointeger(local!countries.regionId)
          ),
          {}
        )
      ),
      choiceValues: a!flatten(
        index(
          local!countries.id,
          wherecontains(
            tointeger(local!selectedRegion),
            tointeger(local!countries.regionId)
          ),
          {}
        )
      ),
      value: local!selectedCountries,
      saveInto: local!selectedCountries,
      placeholder: "---Country---"
    )
  }
)