add grid again when i click addrow an remove the grid

RE: add grid again when i click addrow an remove the grid

Amaan Shekh — Thu, 29 Sep 2022 12:05:24 GMT

check this out

a!localVariables(
  local!contract:{a!map(name:"",address:"",price:"")},
  {
    a!forEach(
      items: local!contract,
      expression:  {
        a!columnsLayout(
          columns: {
            a!columnLayout(
              contents: {
                a!columnsLayout(
                  columns: {
                    a!columnLayout(
                      contents: {
                         a!textField(
                           value: "Contract #"&fv!index,
                           readOnly: true()
                         )
                      }
                    ),
                    a!columnLayout(
                      contents: {
                        a!linkField(
                          align: "RIGHT",
                          links: a!submitLink(
                            label: "remove",
                            saveInto: {a!save(local!contract,remove(local!contract,fv!index))}
                          )
                        )
                      }
                    )
                  }
                ),
                a!gridLayout(
                  headerCells: {
                    a!gridLayoutHeaderCell(label: "name"),
                    a!gridLayoutHeaderCell(label: "address"),
                    a!gridLayoutHeaderCell(label: "price")
                  },
                  rows: {
                    a!gridRowLayout(
                      contents: {
                        a!textField(
                          value: fv!item.name,
                          saveInto: {fv!item.name}
                        ),
                        a!textField(
                          value: fv!item.address,
                          saveInto: {fv!item.address}
                        ),
                        a!textField(
                          value: fv!item.price,
                          saveInto: {fv!item.price}
                        )

                      }
                    )

                  },
                  rowHeader: 1
                )
              }
            )
          }
        ),
      
      }
    ),
    a!linkField(
      label: "",
      labelPosition: "ABOVE",
      links: {
        a!submitLink(
          label: "Add Contract",
          saveInto: a!save(local!contract,append(local!contract,a!map(name:"",address:"",price:"")))
        )
      }
    )
  }
)

RE: add grid again when i click addrow an remove the grid

ujjwalr0002 — Thu, 29 Sep 2022 11:43:56 GMT

Check this

= a!localVariables(
  local!items: {
    a!map(item: null, qty: null, unitPrice: null),
    
  },
  {
    a!forEach(
      items: local!items,
      expression: {
        a!sideBySideLayout(
          items: {
            a!sideBySideItem(
              item: a!richTextDisplayField(label: "Products", ),
              
            ),
            a!sideBySideItem(
              item: a!richTextDisplayField(
                align: "RIGHT",
                value: a!richTextIcon(
                  icon: "times",
                  color: "NEGATIVE",
                  link: a!dynamicLink(
                    saveInto: a!save(
                      local!items,
                      remove(local!items, fv!index)
                    )
                  )
                )
              ),
              
            ),
            
          }
        ),
        a!gridLayout(
          instructions: "Update the item name, quantity, or unit price.",
          headerCells: {
            a!gridLayoutHeaderCell(label: "Item"),
            a!gridLayoutHeaderCell(label: "Qty"),
            a!gridLayoutHeaderCell(label: "Unit Price"),
            a!gridLayoutHeaderCell(label: "Total", align: "RIGHT")
          },
          rows: {
            a!gridRowLayout(
              contents: {
                a!textField(
                  value: fv!item.item,
                  saveInto: fv!item.item
                ),
                a!integerField(value: fv!item.qty, saveInto: fv!item.qty),
                a!floatingPointField(
                  value: fv!item.unitPrice,
                  saveInto: fv!item.unitPrice
                ),
                a!textField(
                  value: fv!item.qty,
                  readOnly: true,
                  align: "RIGHT"
                )
              }
            ),
            
          },
          rowHeader: 1
        ),
        
      }
    ),
    a!richTextDisplayField(
      value: a!richTextItem(
        text: "ADD GRID",
        link: a!dynamicLink(
          label: "Add new Grid",
          saveInto: a!save(
            local!items,
            append(
              local!items,
              a!map(item: null, qty: null, unitPrice: null)
            )
          )
        )
      )
    )
  }
)

RE: add grid again when i click addrow an remove the grid

KM — Thu, 29 Sep 2022 11:30:39 GMT

yeah, am not sure how can i achieve that. am stuck with this task :( unable to progress on this.

my use case when user wants to add more contract then hole grid has to be populated so they'll add if they willing it remove then it should be able to delete it

RE: add grid again when i click addrow an remove the grid

Harshit Bumb (Appyzie) — Thu, 29 Sep 2022 11:27:01 GMT

That is a simple requirement, achievable with a simple loop. You can call your grid in the loop and the items of that loop should be an array that is increased or decreased based on of you add or remove.

Also, you have to create custom dynamic links to add or remove the grid. But just out of curiosity, what is your usecase? Why do you want multiple grids?