How to get CDT array fields based on specific column value

RE: How to get CDT array fields based on specific column value

Peter Lewis — Fri, 04 Nov 2022 12:53:42 GMT

For what it's worth, this example is from the documentation page for cascading dropdowns. There's some more information on that page on how to implement it as well here: https://docs.appian.com/suite/help/latest/recipe-configure-cascading-dropdowns.html

RE: How to get CDT array fields based on specific column value

Stefan Helzle — Thu, 03 Nov 2022 11:58:35 GMT

The following code snippet should get you started.

a!localVariables(
  local!data: {
    a!map(model: "PCX", make: "Honda"),
    a!map(model: "GSX", make: "Honda"),
    a!map(model: "Avenis", make: "Suzuki"),
    a!map(model: "ADV", make: "Honda"),
    a!map(model: "Thruxton", make: "Suzuki"),
  },
  index(
    local!data,
    wherecontains(
      "Honda",
      local!data.make
    )
  )
)

RE: How to get CDT array fields based on specific column value

Amaan Shekh — Thu, 03 Nov 2022 11:54:18 GMT

use this in second dropdown in choicesvalues and choiceslabels

index(index(local!motorcycles,wherecontains(ri!brand,local!motorcycles),{}),"model",{})

RE: How to get CDT array fields based on specific column value

baji mekala — Thu, 03 Nov 2022 11:51:55 GMT

Hi Anwille,

can you pls refer the below code.

a!localVariables(
  local!selectedDepartment,
  local!selectedTitle,
  /*
    * Hardcoded values are stored here through the choose function. Typically    
    * this data would live with the department in a lookup value. In that case
    * local!selectedDepartment would act as a filter on that query to bring
    * back titles by department.
    */
  local!availableTitles:choose(
    if(isnull(local!selectedDepartment), 1, local!selectedDepartment),
    {"CEO","CFO","COO","Executive Assistant"},
    {"Director","Quality Engineer","Manager","Software Engineer"},
    {"Accountant","Manager","Director"},
    {"Coordinator","Director","Manager"},
    {"Consultant","Principal Consultant","Senior Consultant"},
    {"Account Executive","Director","Manager"}
  ),
  a!sectionLayout(
    label: "Example: Cascading Dropdowns",
    contents: {
      a!dropdownField(
        label: "Department",
        choiceLabels: { "Corporate", "Engineering", "Finance", "Human Resources", "Professional Services", "Sales" },
        choiceValues: { 1, 2, 3, 4, 5, 6 },
        placeholder: "-- Select a Department -- ",
        value: local!selectedDepartment,
        saveInto: {
          local!selectedDepartment,
          a!save(local!selectedTitle, null)
        }
      ),     
      a!dropdownField(
        label: "Title",
        choiceLabels: local!availableTitles,
        choiceValues: local!availableTitles,
        placeholder: "--- Select a Title ---",
        value: local!selectedTitle,
        saveInto: local!selectedTitle,
        disabled: isnull(local!selectedDepartment)
      )
    }
  )
)