Need help on read only grid

RE: Need help on read only grid

Mike Schmitt — Thu, 11 May 2023 17:31:20 GMT

Sanchit and Tejpals already gave you workable solutions above (and props to Harshit for pointing out that, really at this point everyone should be using a!localVariables for this...)

But I wanted to chime in with a recommendation towards a usual approach of mine, which is to abstract complicated processing behind additional local variables when necessary. In this case the idea is to construct a whole new array-of-maps that will contain the "Name" property as well as a pre-evaluated copy of the Statuses looked up from the predefined Status List, formatted cleanly and separated by a comma (just for example). Then we just use that new local variable as the source for the grid; any changes made to the original data will cause this to auto-update too, so we should be good there.

One of the main draws to this approach is we don't have to do potentially complex processing in the grid column itself (which isn't always bad to do, but often will make it easier to understand the code in the future, among other things):

The entire code body isn't much changed, other than the addition of the declaration for local!gridData:

a!localVariables(
  local!empStatus: {
    { name: "Ajay", status: "test1" },
    { name: "Ajay", status: "test2" },
    { name: "kumar", status: "test3" },
    { name: "phani", status: "test4" }
  },
  local!empDetail: {
    { name: "Ajay" },
    { name: "kumar" },
    { name: "phani" }
  },
  
  local!gridData: a!forEach(
    local!empDetail,
    a!map(
      name: fv!item.name,
      statusList: joinarray(
        index(
          local!empStatus.status,
          wherecontains(fv!item.name, local!empStatus.name),
          {}
        ),
        ", "
      )
    )
  ),
  
  a!boxLayout(
    label: "Form",
    contents: {
      a!gridField(
        label: "grid",
        data: local!gridData,
        pageSize: 5,
        columns: {
          a!gridColumn(
            label: "Name",
            sortField: "name",
            value: fv!row.name
          ),
          a!gridColumn(
            label: "Status",
            value: fv!row.statusList
          )
        }
      )
    }
  )
)

RE: Need help on read only grid

Shaik Gousi — Thu, 11 May 2023 08:58:44 GMT

Sure Thank You!!

RE: Need help on read only grid

Shaik Gousi — Thu, 11 May 2023 07:20:18 GMT

Thank You!!

RE: Need help on read only grid

Harshit Bumb (Appyzie) — Thu, 11 May 2023 07:08:51 GMT

Also, a couple of observations

a!forEach(
              items: local!empStatus,
              expression: fv!item.status
            )

Here, forEach is not being used. It is useless. Rather you can just write local!empStatus.status.

pagingSaveInto: fv!pagingInfo,

fv!pagingInfo gives you the current pagingInfo. You should use a variable instead that you are passing in your query as pagingInfo

RE: Need help on read only grid

Harshit Bumb (Appyzie) — Thu, 11 May 2023 06:11:35 GMT

Why are you still using load instead of localVariables?

RE: Need help on read only grid

sanchitg0002 — Thu, 11 May 2023 06:04:51 GMT

You can edit that as well

RE: Need help on read only grid

tejpals0001 — Thu, 11 May 2023 06:00:18 GMT

okay thanks, next time I will.🙂

RE: Need help on read only grid

sanchitg0002 — Thu, 11 May 2023 05:57:52 GMT

It is more readable in a code box🙂

RE: Need help on read only grid

tejpals0001 — Thu, 11 May 2023 05:53:59 GMT

load(
  local!empStatus: {
    { name: "Ajay", status: "test1" },
    { name: "Ajay", status: "test2" },
    { name: "kumar", status: "test3" },
    { name: "phani", status: "test4" }
  },
  local!empDetail: {
    { name: "Ajay" },
    { name: "kumar" },
    { name: "phani" }
  },
  a!boxLayout(
    label: "Form",
    contents: {
      a!gridField(
        label: "grid",
        data: local!empDetail,
        pageSize: 5,
        pagingSaveInto: fv!pagingInfo,
        columns: {
          a!gridColumn(label: "Name", value: fv!row.name),
          a!gridColumn(
            label: "Status",
            value: a!forEach(
              items: local!empStatus,
              expression:   if(fv!row.name=fv!item.name,fv!item.status,{})
            )
          
          )
        }
      )
    }
  )
)

RE: Need help on read only grid

Shaik Gousi — Thu, 11 May 2023 05:48:48 GMT

Thank You!!!

RE: Need help on read only grid

sanchitg0002 — Thu, 11 May 2023 05:44:33 GMT

load(
  local!empStatus: {
    { name: "Ajay", status: "test1" },
    { name: "Ajay", status: "test2" },
    { name: "kumar", status: "test3" },
    { name: "phani", status: "test4" }
  },
  local!empDetail: {
    { name: "Ajay" },
    { name: "kumar" },
    { name: "phani" }
  },
  a!boxLayout(
    label: "Form",
    contents: {
      a!gridField(
        label: "grid",
        data: local!empDetail,
        pageSize: 5,
        pagingSaveInto: fv!pagingInfo,
        columns: {
          a!gridColumn(label: "Name", value: fv!row.name),
          a!gridColumn(
            label: "Status",
            value: joinarray(
              index(
                local!empStatus.status,
                wherecontains(
                  fv!row.name,
                  touniformstring(local!empStatus.name)
                ),
                {}
              ),
              ","
            )
          )
        }
      )
    }
  )
)