Radio Buttons and Read Only Grid

RE: Radio Buttons and Read Only Grid

Mike Schmitt — Tue, 29 Aug 2023 18:50:46 GMT

I had this already written before I realized OP was not after row-by-row selection. Pasting it here anyway as a pattern for others to use if needed. I think it looks pretty decent and I only wish it were possible 5 or 6 years ago, lol.

a!localVariables(
  
  local!gridData: a!forEach(
    enumerate(9),
    a!map(
      id: fv!index,
      name: "Row " & fv!index
    )
  ),
  
  local!selection: tointeger(null()),
  
  a!gridField(
    data: local!gridData,
    selectable: false(),
    
    columns: {
      a!gridColumn(
        helpTooltip: "Fake Selection Column",
        width: "ICON",
        align: "CENTER",
        value: a!richTextDisplayField(
          value: a!richTextItem(
            text: {
              a!richTextIcon(
                icon: "circle-o",
                showWhen: local!selection <> fv!row.id,
                size: "MEDIUM",
                link: a!dynamicLink(
                  saveInto: {
                    a!save(
                      local!selection,
                      fv!row.id
                    )
                  }
                ),
                linkStyle: "STANDALONE",
                caption: "Click to Select"
              ),
              a!richTextIcon(
                icon: "dot-circle-o",
                showWhen: local!selection = fv!row.id,
                size: "MEDIUM",
                color: "ACCENT",
                caption: "Currently Selected"
              )
            }
          )
        )
      ),
      
      a!gridColumn(
        label: "Id",
        value: fv!row.id
      ),
      a!gridColumn(
        label: "Name",
        value: fv!row.name
      )
    }
  )
)

RE: Radio Buttons and Read Only Grid

Stefan Helzle — Tue, 29 Aug 2023 17:59:54 GMT

a!localVariables(
  local!olderThan45: false,
  a!richTextDisplayField(
    label: "Radio Button",
    value: {
      a!richTextIcon(
        icon: if(local!olderThan45, "circle", "circle-o"),
        link: a!dynamicLink(
          value: true,
          saveInto: local!olderThan45
        ),
        linkStyle: "STANDALONE",
      ),
      a!richTextItem(
        text:" Yes",
        link: a!dynamicLink(
          value: true,
          saveInto: local!olderThan45
        ),
        linkStyle: "STANDALONE",
      ),
      char(10),
      a!richTextIcon(
        icon: if(local!olderThan45, "circle-o", "circle"),
        link: a!dynamicLink(
          value: false,
          saveInto: local!olderThan45
        ),
        linkStyle: "STANDALONE",
      ),
      a!richTextItem(
        text:" No",
        link: a!dynamicLink(
          value: false,
          saveInto: local!olderThan45
        ),
        linkStyle: "STANDALONE",
      ),
    }
  )
)

RE: Radio Buttons and Read Only Grid

Maria — Tue, 29 Aug 2023 17:40:46 GMT

Yes, but I need to show both buttons just like radio buttons and icons dont do that, they dont change when they are selected or something like that

RE: Radio Buttons and Read Only Grid

Mike Schmitt — Tue, 29 Aug 2023 17:39:53 GMT

If this is a yes/no question that will need to be saved into every row of an array of data, then you should probably be using an Editable Grid instead of a read-only grid.

RE: Radio Buttons and Read Only Grid

Stefan Helzle — Tue, 29 Aug 2023 17:39:40 GMT

Icons in rich text fields support dynamic links that allow you to modify data ...

RE: Radio Buttons and Read Only Grid

Maria — Tue, 29 Aug 2023 17:33:10 GMT

Is just a question of yes or no for the user, for example: are you older than 45? yes no (like the radio buttons) but for it to look "good" they want it to be inside a column of the grid, is not like the selection of the row of the grid or anything like that.

RE: Radio Buttons and Read Only Grid

Mike Schmitt — Tue, 29 Aug 2023 17:30:29 GMT

Can you provide a bit more detail as to what you're trying to allow them to select/unselect? The concept of selection in a read-only grid is generally keyed specifically towards selection of an entire row (or set of rows), but it sounds like you might really be after something else here - I'm having a hard time telling what, though.

RE: Radio Buttons and Read Only Grid

Stefan Helzle — Tue, 29 Aug 2023 17:29:54 GMT

Inside a read-only grid ?!?!? There is a reason for that name.

RE: Radio Buttons and Read Only Grid

Maria — Tue, 29 Aug 2023 17:29:05 GMT

I was thinking of doing that but since is more of a Yes or No question for the user, with Icons I dont think I can do that. In the case if they need to unselect the selected choice.

or is it possible?

RE: Radio Buttons and Read Only Grid

Maria — Tue, 29 Aug 2023 17:27:21 GMT

I need them to be able to select or unselect in case they need to.

RE: Radio Buttons and Read Only Grid

Mike Schmitt — Tue, 29 Aug 2023 17:25:58 GMT

As a workaround, consider that that Read Only Grid can very easily show the Rich Text Display Field and any of its possible configurations, including all of the Rich Text Icon choices, which include various options that replicate radio buttons and checkboxes.

RE: Radio Buttons and Read Only Grid

Stefan Helzle — Tue, 29 Aug 2023 17:25:54 GMT

Why not just show the selected options in a bullet point list inside a rich text display field?

RE: Radio Buttons and Read Only Grid

Mathieu Drouin — Tue, 29 Aug 2023 17:06:13 GMT

Not possible. Contrary to the editable grid, the read only grid does not support as many components.

From the documentation:

https://docs.appian.com/suite/help/23.3/Grid_Column_Component.html

The value can be text, a!imageField(), a!linkField(), a!richTextDisplayField(), a!tagField(), a!buttonArrayLayout(), a!recordActionField(), or a!progressBarField().