Creating a BoxLayout

RE: Creating a BoxLayout

Yash Gandhi — Mon, 01 Apr 2024 11:52:42 GMT

thank you daisymanmohansingh, your code is working

RE: Creating a BoxLayout

Yash Gandhi — Mon, 01 Apr 2024 11:51:32 GMT

Stefan and Konduru, code is working, thank you

RE: Creating a BoxLayout

daisyMSingh — Mon, 01 Apr 2024 07:37:15 GMT

In Given Manner You Can Achieve the Following Requirements .

a!localVariables(
  local!result: {
    { values: { "firstname", "lastname", "city" } },
    { values: { "rakesh", "sharma", "mumbai" } },
    { values: { "rahul", "dongre", "gondia" } },
    { values: { "priti", "kataria", "delhi" } },

  },
  local!data: a!forEach(
    items: local!result,
    expression: a!map(
      firstname: fv!item.values[1],
      lastname: fv!item.values[2],
      city: fv!item.values[3]
    )
  ),
  local!columnsName: { "firstname", "lastname", "city" },
  a!forEach(
    items: local!data,
    expression: if(
      fv!isFirst,
      {},
      a!localVariables(
        local!indexData: fv!item,
        a!boxLayout(
          contents: {
            a!columnsLayout(
              columns: {
                a!forEach(
                  items: local!columnsName,
                  expression: a!columnLayout(
                    contents: {
                      a!textField(
                        label: fv!item,
                        labelPosition: "ADJACENT",
                        value: index(local!indexData, fv!item, null),
                        readOnly: true()
                      )
                    }
                  )
                )
              }
            )
          },
          isCollapsible: true()
        )
      )
    )
  )
)

RE: Creating a BoxLayout

Konduru Chaitanya — Fri, 29 Mar 2024 14:51:11 GMT

I think what Stefan has mentioned is just what you have asked for here in this space. It is working perfectly for me. What is that you are seeing on screen when you are using Stefan's code? You can just update the local with your ER or the source of the data. That should definetely work.

RE: Creating a BoxLayout

Stefan Helzle — Fri, 29 Mar 2024 12:40:33 GMT

The data structure I created should be quite similar to the one you have.

RE: Creating a BoxLayout

Yash Gandhi — Fri, 29 Mar 2024 11:48:49 GMT

thank you shyam but i want boxlayout only

RE: Creating a BoxLayout

Yash Gandhi — Fri, 29 Mar 2024 11:47:30 GMT

It is not working stefan, I want without hardcoding values, i have shared a screenshot of document when file gets uploaded ER get called

RE: Creating a BoxLayout

ShyamSudi — Fri, 29 Mar 2024 10:25:20 GMT

Hi Yash Gandhi,

Try using grids

a!columnsLayout(
      spacing: "NONE",
      columns: {
        a!columnLayout(
          contents: a!gridField(
            data: local!result,
            columns: a!gridColumn(value: fv!row.values[1])
          )
        ),
        a!columnLayout(
          contents: 
          a!gridField(
            data: local!result,
            columns: a!gridColumn(value: fv!row.values[2])
          )
        ),
        a!columnLayout(
          contents: a!gridField(
            data: local!result,
            columns: a!gridColumn(value: fv!row.values[3])
          )
        ),
      }
    ),

It looks like this

RE: Creating a BoxLayout

Stefan Helzle — Fri, 29 Mar 2024 08:54:08 GMT

a!localVariables(
  local!result: {
    {
      values: {
        "firstname",
        "lastname",
        "city"
      }
    },
    {
      values: {
        "rakesh",
        "sharma",
        "mumbai"
      }
    },
    {
      values: {
        "rahul",
        "dongre",
        "gondia"
      }
    },
    {
      values: {
        "priti",
        "kataria",
        "delhi"
      }
    },
  },
  a!forEach(
    items: remove(local!result, 1),
    expression: a!localVariables(
      local!row: fv!item,
      a!boxLayout(
        marginBelow: "STANDARD",
        contents: {
          a!forEach(
            items: local!result[1].values,
            expression: a!textField(
              label: proper(fv!item),
              value: local!row.values[fv!index]
            )
          )
        }
      )
    )
  )
)

RE: Creating a BoxLayout

Yash Gandhi — Fri, 29 Mar 2024 05:50:24 GMT

I am not understanding Konduru, i am using cardlayout for boxes

RE: Creating a BoxLayout

Konduru Chaitanya — Fri, 29 Mar 2024 05:47:47 GMT

In the items, get rid of [1] . That should do.Also define the first a!forEach in a correct format. But where is the box layout?

RE: Creating a BoxLayout

Yash Gandhi — Fri, 29 Mar 2024 05:23:16 GMT

okay, i will give you a logic of that code not whole code you can see what is need to be updated

RE: Creating a BoxLayout

Stefan Helzle — Thu, 28 Mar 2024 14:41:34 GMT

Sorry, but without seeing your code, I cannot say anything.

RE: Creating a BoxLayout

Yash Gandhi — Thu, 28 Mar 2024 14:29:10 GMT

Sorry Stefan, i cannot share a code it's a organisation policy but for labels i am using fv!item and for values I am using local variables where values of document data is populating with fv! index in textbox

If you can share a code with above scenario what I have written how can be it is shown as sample with for each then i can use it as a reference in UI

RE: Creating a BoxLayout

Stefan Helzle — Thu, 28 Mar 2024 14:18:29 GMT

Can you share the code of that interface?

I assume you are using a foreach to iterate on the rows. Do you use fv!item to reference the values?