Return one value for multiple conditions

Question

In the image bellow the 3fields in the square come from a dropdown ("SI" or "NO") in a user interface. 
 I can see the user responses in a read-only grid (see the image bellow). 
 I want IF 3 condition ("Financial", "Documents", "Certificate") in the red square are "SI" then the column "Estado" return a new value "Finalizado" 
 IF just one condition ("Financial", "Documents", "Certificate") in the red square are "NO" then the column "Estado" return a new value "Pendiente"

Next i want to store the value of the column "Estado" in my cloud database

Mike Schmitt · Accepted Answer

Here's a standalone example mirroring your values which demonstrates how to do this calculation in a single-nested if() statement as well as how to properly contain the calculation within its own local variable. Note how the text field does not and should not have a "saveInto" parameter set, as it would never do anything at all since it's read-only. 
 a!localVariables(
 local!entry: a!map(
 financial: "",
 documents: "",
 certificate: ""
 ),
 
 /* this value will auto-update as the dropdown values are changed */
 local!calculatedStatus: if(
 or(
 a!isNullOrEmpty(local!entry.financial),
 a!isNullOrEmpty(local!entry.documents),
 a!isNullOrEmpty(local!entry.certificate)
 ),
 "In Processing",
 if(
 and(
 local!entry.financial = "YES",
 local!entry.documents = "YES",
 local!entry.certificate = "YES"
 ),
 "Finalized",
 "Pending"
 )
 ),
 
 {
 a!dropdownField(
 label: "Financial",
 labelPosition: "ADJACENT",
 placeholder: "(none)",
 choiceLabels: {"Yes", "No"},
 choiceValues: {"YES", "NO"},
 value: local!entry.financial,
 saveInto: local!entry.financial
 ),
 a!dropdownField(
 label: "Documents",
 labelPosition: "ADJACENT",
 placeholder: "(none)",
 choiceLabels: {"Yes", "No"},
 choiceValues: {"YES", "NO"},
 value: local!entry.documents,
 saveInto: local!entry.documents
 ),
 a!dropdownField(
 label: "Certificate",
 labelPosition: "ADJACENT",
 placeholder: "(none)",
 choiceLabels: {"Yes", "No"},
 choiceValues: {"YES", "NO"},
 value: local!entry.certificate,
 saveInto: local!entry.certificate
 ),
 
 a!textField(
 label: "Status",
 readOnly: true(),
 /* this field is READ ONLY, so there is **no save-into**, as it wouldn't do anything anyway */
 /* saveInto: "", */
 value: local!calculatedStatus
 )
 }
)

Mike Schmitt · Answer

Just to be sure, please be aware that a TextField's "saveInto" parameter does not make any changes whatsoever until/unless the text field itself is interacted with . Thus if you're hoping the "saveInto" of your text field is going to insert some novel calculated value elsewhere, it's not going to work. Generally the best place to put such logic is in a button, to be evaluated and saved upon user click. 
 In your case, if you wish to display the value and then also save it into a data output upon submission of the form, it would be advisable to calculate / store the value in a local variable, show the value in a read-only text field, and also store the value of the local variable into your rule input upon "submit" click.

Deepak gupta · Answer

To store the data into DB, you have to create a link or button for the action to writeDataintoDatastore but to show the value into Estado column. you can use the below code under value configuration of the grid column of Estado. 
 if(
and(
fv!row.financial="SI",
fv!row.documents="SI",
fv!row.certificate="SI",
),
"Finalizado",
"Pendite"


)

Return one value for multiple conditions

Top Replies