How to generate base64 digest string in Appian.

Question

Hello All, 
 
 Below is the code snippet from Ruby. 
 
 Digest::SHA256.base64digest('') 
 
 I need to generate the same in Appian and pass it to the integration header parameter, please let me know if anyone has done this before. 
 
 Thank You, 
 Sneha.

Mike Schmitt · Answer

I just wrote one myself a year or so ago. Let me see if I can find where I saved the rule code... edit: here you go-- /* encode */
a!localVariables(
 /*local!text: "Man is distinguished, not only by his reason, but by this singular passion from other animals, which is a lust of the mind, that by a perseverance of delight in the continued and indefatigable generation of knowledge, exceeds the short vehemence of any carnal pleasure.",*/
 local!text: ri!text,

 local!charset: "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/",
 local!codeArray: code(local!text),
 local!bins: concat(dec2bin(local!codeArray, 8)),
 local!groupedBins: split(concat(
 a!forEach(
 code(local!bins), 
 char(fv!item) & if(and(mod(fv!index, 6) = 0, not(fv!isLast)), "-=-=-", "")
 )
 ), "-=-=-" ),
 local!lastBin: index(local!groupedBins, length(local!groupedBins)),
 local!padding: if(
 len(local!lastbin) = 2,
 "==",
 len(local!lastbin) = 4,
 "=",
 len(local!lastbin) = 6,
 "",
 "error condition"
 ),
 local!bindexes: a!forEach(
 local!groupedBins,
 if(
 fv!isLast,
 bin2dec(substitute(padright(fv!item, 6), " ", "0")),
 bin2dec(fv!item)
 )
 ) + 1,

 local!assembledOutput: concat(a!forEach(local!bindexes, charat(local!charset, fv!item))) & local!padding,

 local!assembledOutput
)

Mike Schmitt · Answer

Jason said: do you happen to have a base64 decoder written as well? 
 In fact, yes. 
 /* decode */
a!localVariables(
 local!base64text: ri!base64text,

local!charset: "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/",

local!charCodes: code(local!base64text),
 /*local!paddingCount: count(wherecontains(code("="), local!charCodes)),*/
 local!unpaddedChars: a!flatten(a!forEach(
 items: local!charCodes,
 expression: if(fv!item = code("="), {}, find(char(fv!item), local!charset)-1)
 )),
 local!rawBins: dec2bin(tointeger(local!unpaddedChars), 6),

local!decodedBins: split(
 concat(
 a!forEach(
 items: code(concat(local!rawBins)),
 expression: if(
 mod(fv!index, 8) = 0,
 char(fv!item) & "-=-=-",
 char(fv!item)
 )
 )
 ),
 "-=-=-"
 ),

concat(
 a!forEach(
 items: local!decodedBins,
 expression: if(
 or(fv!item = "0000", fv!item = "00"),
 null(),
 char(bin2dec(fv!item))
 )
 )
 )
)

Mike Schmitt · Answer

sri123 said: Yes, it is actually converting base64 to text, but I need to convert text to base 64. 
 I have at least 2 different rules posted above. One converts base64 to text, and the other converts text to base64. Are you saying you've tried both of them? It seems to me like you've probably missed one .

Mike Schmitt · Answer

Neha Dangi said: This code snippet, will help us to convert simple text to base64 ? 
 Yes, the code I posted (which is custom code I wrote 100% from scratch on my own in Appian) should generate standard Base64 given an input string. I've tested the base64 it generates with external base64 convertors and at least thus far I haven't found any areas where it doesn't work correctly.

How to generate base64 digest string in Appian.

Top Replies