How to configure a dropdown list to save multiple times

Question

Hi all, 
 
 I'm trying to use a single dropdown list to add multiple users to my grid, right now when I Select one it saves it, but if I select the dropdown again it will overwrite my first selection, how can I over come this? 
 Basically I want to select -> save , select again -> save and so on.

Mathieu Drouin · Accepted Answer

You probably want your saveInto to append to an array. 
 a!localVariables(
 local!value,
 local!values,
 {
 a!dropdownField(
 label: "Dropdown",
 placeholder: "Choose value",
 choiceLabels: { "Value 1", "Value 2", "Value 3" },
 choiceValues: { "Value 1", "Value 2", "Value 3" },
 value: index(local!value, "name", null),
 saveInto: {
 a!save(local!value, a!map(name: save!value)),
 a!save(
 local!values,
 append(local!values, local!value)
 )
 }
 ),
 a!gridField(
 data: local!values,
 columns: { a!gridColumn(value: fv!row.name) }
 )
 }
)

Mathieu Drouin · Answer

a!localVariables(
 local!choices: {
 a!map(id: 1, name: "Ana", email: "ana@test.com"),
 a!map(id: 2, name: "Joe", email: "joe@test.com"),
 a!map(id: 3, name: "Jane", email: "jane@test.com")
 },
 local!value,
 local!values,
 {
 a!dropdownField(
 label: "Dropdown",
 placeholder: "Choose value",
 choiceLabels: index(local!choices, "name", {}),
 choiceValues: index(local!choices, "id", {}),
 value: local!value,
 saveInto: {
 local!value,
 a!save(
 local!values,
 append(
 local!values,
 index(
 local!choices,
 wherecontains(
 save!value,
 cast(
 a!listType(typeof(1)),
 index(local!choices, "id", {})
 )
 )
 )
 )
 )
 }
 ),
 a!gridField(
 data: local!values,
 columns: { a!gridColumn(value: fv!row.name) }
 )
 }
)

Mathieu Drouin · Answer

You can't use buttons in a grid. 
 a!localVariables(
 local!choices: {
 a!map(id: 1, name: "Ana", email: "ana@test.com"),
 a!map(id: 2, name: "Joe", email: "joe@test.com"),
 a!map(id: 3, name: "Jane", email: "jane@test.com")
 },
 local!value,
 local!values,
 {
 a!dropdownField(
 label: "Dropdown",
 placeholder: "Choose value",
 choiceLabels: index(local!choices, "name", {}),
 choiceValues: index(local!choices, "id", {}),
 value: local!value,
 saveInto: {
 local!value,
 a!save(
 local!values,
 append(
 local!values,
 index(
 local!choices,
 wherecontains(
 save!value,
 cast(
 a!listType(typeof(1)),
 index(local!choices, "id", {})
 )
 )
 )
 )
 )
 }
 ),
 a!gridField(
 data: local!values,
 columns: {
 a!gridColumn(value: fv!row.name),
 a!gridColumn(
 width: "ICON",
 value: a!richTextDisplayField(
 value: a!richTextIcon(
 icon: "times",
 color: "NEGATIVE",
 link: a!dynamicLink(
 saveInto: { 
 a!save(
 local!values,
 remove(
 local!values,
 fv!identifier
 )
 ) 
 }
 ),
 linkStyle: "STANDALONE"
 )
 )
 )
 }
 )
 }
) 
 If this helped, please mark the answer as verified to help others who might have the same question.

How to configure a dropdown list to save multiple times

Top Replies