JAXB Errors in process models

I think that is not related with special characters but with the structure of the data. JAXB is a library designed for binding to XML your data structures.

If the strcuture of your data does not fit with overlying xsd schema, you will receive this kind of errors (JAXB Exception)

Thank you for your answer David! How would you go for resolving errors like this? Since the processes will break at different nodes and for dictionaries with different data types might there be an underlying problem with the Record Types we provide as input?
For this example the input for the node was a dictionary with data for 2 record types and pp!name.
From what I can see all the errors are in nodes where a dictionary is the input data for a startprocess.The data that goes in the dictionary are data types for which you would not expect errors like this e.g. Record Types, text, boolean etc.

We have found a solution for this error, it comes down to removing unprintable items before passing them to the start proces nodes.

The function we use to solve this problem (I added the rules we use here below):
rule!DEC_RemoveSmileys:
a!forEach(
  items: ri!rappellen,
  expression: a!update(
    fv!item,
    "RAPL_OMSCHRIJVING",
    a!localVariables(
      local!cleaned: rule!DCO_Clean(
        inputData: fv!item["RAPL_OMSCHRIJVING"],
        specialCharMaps: { a!map(char: "€", string: " [#EURO#] ") }
      ),
      if(
        and(
          not(rule!DCO_IsVoid(local!cleaned)),
          find("[#EURO#]", local!cleaned) > 1
        ),
        substitute(local!cleaned, " [#EURO#] ", "€"),
        local!cleaned
      )
    )
  )
),
rappellen: Text (array)

rule!DCO_Clean: 
if(
  rule!DCO_IsVoid(ri!inputData),
  null,
  a!flatten(
    a!forEach(
      items: ri!inputData,
      expression: if(
        rule!DCO_IsVoid(ri!specialCharMaps),
        clean(fv!item),
        clean(
          reduce(
            rule!DCO_CleanReduceSubFunction,
            fv!item,
            ri!specialCharMaps
          )
        )
      )
    )
  )
),
inputData: Text (Array),
specialCharMaps: Map (Array)
__
rule!DCO_CleanReduceSubFunction: 
if(
  rule!DCO_IsVoid(ri!string),
  "",
  substitute(
    ri!string,
    ri!specialCharMap["char"],
    ri!specialCharMap["string"]
  )
),
String: Text,
sepcialCharMap: Map
__
rule!DCO_IsVoid: a!match(
  value: runtimetypeof(ri!value),
  whenTrue: a!isNullOrEmpty(ri!value),
  then: true,
  /* Strings */
  whenTrue: fv!value = 'type!{http://www.appian.com/ae/types/2009}Text',
  /* Ignore white space */
  then: len(trim(ri!value)) = 0,
  /* List of Variant */
  whenTrue: fv!value = 'type!{http://www.appian.com/ae/types/2009}Variant?list',
  then: all(a!isNullOrEmpty(_), a!flatten(ri!value)),
  /* Lists */
  /* Try to take first item in list and cast it to a list of itself */
  /* then compare its datatype to the incoming data type */
  whenTrue: fv!value = runtimetypeof(
    cast(
      runtimetypeof({ index(ri!value, 1, null) }),
      ri!value
    )
  ),
  /* Flatten takes care of lists in lists in lists in ... */
  /* List has zero non-null items, length() already ignores null values*/
  then: length(a!flatten(ri!value)) = 0,
  /* DataSubsets or Maps returned by queryRecordType */
  whenTrue: or(
    fv!value = 'type!{http://www.appian.com/ae/types/2009}DataSubset',
    and(
      fv!value = 'type!{http://www.appian.com/ae/types/2009}Map',
      contains(a!keys(ri!value), "data"),
      
    )
  ),
  then: a!isNullOrEmpty(ri!value.data),
  /* Empty map without any keys and values */
  whentrue: fv!value = 'type!{http://www.appian.com/ae/types/2009}Map',
  then: or(
    length(a!keys(ri!value)) = 0,
    
    /*  The commented line below will make a map filled with keys but no values seen as void  */
    /*all(a!isNullOrEmpty(_), index(ri!value, a!keys(ri!value), null))*/
    
  ),
  default: false
)
Value: Any type