Column Layout, Fix One Column Not Scrollable

Using a!cardLayout() with a fixed height will cause the contents to be scrollable. You can also hide the border of the card.

docs.appian.com/.../card_layout.html

{
  a!columnsLayout(
    columns: {
      a!columnLayout(
        contents: {
          a!cardLayout(
            contents: {
              a!forEach(
                enumerate(12),
                a!textField(
                  label: "Field "&fv!item
                )
              )
            },
            height: "TALL",
            style: "NONE",
            showBorder: false,
            marginBelow: "STANDARD"
          )
        }
      ),
      a!columnLayout(
        contents: {
          a!textField(
            label: "Text",
            labelPosition: "ABOVE",
            saveInto: {},
            refreshAfter: "UNFOCUS",
            validations: {}
          )
        },
        width: "NARROW"
      )
    }
  )
}

This is great!  Could use an EXTRA_TALL height.

UPDATE: In 24.1, the new Pane Layout component is meant to address precisely this kind of a scenario. You can have your data in one pane and the list of links in a second pane. Both will scroll independently if they exceed the size of the screen. 

An example of how this could be used

{
  a!paneLayout(
    panes: {
      a!pane(
        contents: {
            a!forEach(
                enumerate(12),
                a!textField(
                  label: "Field "&fv!item
                )
            )
        }
      ),
      a!pane(
        contents: {
          a!textField(
            label: "Text",
            labelPosition: "ABOVE",
            saveInto: {},
            refreshAfter: "UNFOCUS",
            validations: {}
          )
        },
        width: "NARROW"
      )
    }
  )
}