Custom picker for Searching users

Do you plan to always query the entire list of users into a local variable and pass the entire list into ucArrayPickerFilter?  That won't perform very well if the users database is planned to grow even somewhat large.  Usually the way to do this would be to have the picker actually query into the users table live while the user enters search terms.  Then (to satisfy your use case) you'd be able to use QueryLogicalExpressions to allow searching via different values, i.e. the person's actual name, username, id, etc.

Could you please explain in details with an example query Logic expression.. Thank you in advance.

Could you please explain in details with an example query Logic expression.. Thank you in advance.

Here's a simple version.  This will allow the end user to type a partial first name OR partial last name OR partial username, OR the user ID.  The first and last names must begin with the search string, but the search string can match any part of the username.

a!queryLogicalExpression(
  operator: "OR",
  filters: {
    a!queryFilter(
      field: "firstName",
      operator: "starts with",
      value: ri!input
    ),
    a!queryFilter(
      field: "lastName",
      operator: "starts with",
      value: ri!input
    ),
    a!queryFilter(
      field: "username",
      operator: "includes",
      value: ri!input
    ),
    a!queryFilter(
      field: "userId",
      operator: "=",
      value: tointeger(ri!input),
      applyWhen: not(isnull(tointeger(ri!input)))
    )
  }
)

Here's a more complex version I've used recently with a nested logical expression - basically this lets a user enter a few search terms separated by a space, and the query will return anything that matches all of them.  So if you're searching for "Mike Schmitt", you could type "Mi Sc", which would match me as well as "Minnie Schaffer" for example.  You could easily extend this to also allowing the username and/or user ID to be included as search terms following my simpler example above.

a!queryLogicalExpression(
  operator: "AND",
  logicalExpressions: a!forEach(
    if(isnull(ri!input), {}, split(ri!input, " ")),
    a!queryLogicalExpression(
      operator: "OR",
      filters: {
        a!queryFilter(
          field: "firstName",
          operator: "includes",
          value: fv!item,
          applyWhen: not( isnull( fv!item ) )
        ),
        a!queryFilter(
          field: "lastName",
          operator: "includes",
          value: fv!item,
          applyWhen: not( isnull( fv!item ) )
        )
      }
    )
  )
)