Sorting months based on chronological order

Question

Hi All, 
 I am having a list of months shuffled in a list. I want to arrange them in their chronological order. But I can sort only on alphabetical order. Help me guys. 
 local!months:{"June","January","March","Novemeber","February","October","December","April","July","May","September","August"}, sort(local!months). 
 Thank you

Mike Schmitt · Accepted Answer

Turns out I can't resist a fun challenge... 
 a!localVariables(
 local!orderedMonthNames: a!forEach(
 enumerate(12),
 text(todate(fv!index & "/1/2021"), "mmmm")
 ),
 
 local!months: {"June", "January", "March", "Novemeber", "February", "October", "December", "April", "July", "May", "September", "August"},
 
 local!mapped: a!forEach(
 local!months,
 a!map(
 name: fv!item,
 number: index(wherecontains(fv!item, local!orderedMonthNames), 1, -1)
 )
 ),
 
 todatasubset(
 arrayToPage: local!mapped,
 pagingConfiguration: a!pagingInfo(
 startIndex: 1,
 batchSize: -1,
 sort: a!sortInfo(
 field: "number",
 ascending: true()
 )
 )
 ).data
 
)

Stefan Helzle · Answer

Me neither -) a!localVariables(
 local!orderedMonthNames: a!forEach(
 enumerate(12),
 text(todate(fv!index & "/1/2021"), "mmmm")
 ),

 local!months: {"June", "January", "March", "November", "February", "October", "December", "April", "July", "May", "September", "August"},

 reduce(
 a!update(_,_,_),
 {},
 merge(
 a!forEach(
 items: local!months,
 expression: lookup(local!orderedMonthNames, fv!item)
 ),
 local!months
 )
 )
) 
 Have an empty array and insert the strings at the correct index.

gayathris876948 · Answer

may be you can alter like this 
 
 a!localVariables(
local!months: { "Jan", "Feb", "Apr", "Mar" },/*input*/
local!months_txt: { "Jan", "Feb", "Mar", "Apr" },
/*Constant*/
local!monthIds_int: { 1, 2, 3, 4 },
/*Constant*/
local!data_cdt: a!forEach(
items: local!months,
expression: a!map(
monthId: displayvalue(
fv!item,
local!months_txt,
local!monthIds_int,
""
),
monthName: fv!item
)
),
todatasubset(
local!data_cdt,
a!pagingInfo(
1,
- 1,
a!sortInfo(field: "monthId", ascending: true())
)
).data.monthName
)

Mike Schmitt · Answer

Well, assuming you start off with a passed-in, randomized list of month names in a text array, and nothing else, here is what i'd suggest, just off the top of my head: 
 First, loop over the list of months using a!forEach(). The output of this loop will need to be slightly different dependent on whether we expect it to possibly handle duplicated months. In the loop, compare the month name to a predefined list. The output should be a dictionary or map containing a "name" parameter with the current item name in the loop, then a "number" parameter with the month's integer number in a calendar year (1 - 12). 
 After that, you should be able to use our standard trick for sorting a dictionary by the value of a particular parameter, sorting by the "number" parameter in this case - utilizing the toDataSubset() function (i believe someone posted the approximate code for this up-thread).

Mike Schmitt · Answer

What sort of flexibility do you have? Can you make your local variable, instead of holding a list of string, hold a list of dictionary/maps instead, in which you give each month a "name" and a "number" parameter?

Sorting months based on chronological order

Top Replies