Can we exit from a!forEach() loop?

Hi beenav4597,

I don't think that you can exit the for loop on the specific condition.

What can you do that save the null value when the condition is false and save the value on the true condition and outside the loop you can use the reject function for getting the desire output.

a!localVariables(
  local!test : {
    1,2,3,4
  },
  reject(
    isnull(_),
    a!forEach(
      items: local!test,
      expression: if(
        fv!item = 2,
        fv!item,
        null()
      )
    )
  )
)

You can use wherecontain() function if it fulfills the condition.

https://docs.appian.com/suite/help/22.3/fnc_array_wherecontains.html#:~:text=When%20to%20use%20wherecontains(),field%20in%20that%20CDT%20array.

a!localVariables(
  local!test : {
    1,2,3,4
  },
  local!index : wherecontains(
    2,
    local!test
  ),
  if(
    a!isNullOrEmpty(
      local!index
    ),
    "",
    property(
      local!test, local!index
    )
  )
)

Hopefully it will help.

Not. There is a reason it is called forEach. Depending in your input data there might be other options.

This can be achieved with recursion.  For an example below, run rule!chris_recur() and it will loop only until it returns a user in org "B" with weight 22 (4th user).

rule!chris_recur()

a!localVariables(
  local!users: {
    a!map(user: "Tim", org: "A", weight: 10),
    a!map(user: "Steve", org: "B", weight: 2),
    a!map(user: "Sally", org: "A", weight: 14),
    a!map(user: "Mary", org: "B", weight: 22),
    a!map(user: "George", org: "C", weight: 5),
    a!map(user: "Alex", org: "C", weight: 7)
  },
  rule!chris_recur_sub(
    users: local!users,
    index: 1
  )
)

rule!chris_recur_sub(users,index)

if(
  and(
    ri!users[ri!index].org="B",
    ri!users[ri!index].weight=22
  ),
  ri!users[ri!index], /* Exit - return user */
  if(
    ri!index=count(ri!users), /* Exit - return null/none found */
    null,
    rule!chris_recur_sub( /* Recur to next user */
      users: ri!users,
      index: ri!index+1
    )
  )
)

Always remember to save your recursive functions before testing them!

I guess you can achieve it by using queryAggregation or GROUP BY if done in SQL script, and add randomizer for index.

Something similar to this:

a!localVariables(
  local!boxers: a!queryEntity(
    entity: cons!MFA_BOXER_LIST_DSE,
    query: a!query(
      aggregation: a!queryAggregation(
        aggregationColumns: {
          a!queryAggregationColumn(
            field: "organization",
            isGrouping: true
          ),
          a!queryAggregationColumn(
            field: "categoryId",
            isGrouping: true
          ),
          a!queryAggregationColumn(
            field: "id",
            aggregationFunction: "MAX"
          )
        }
      ),
      pagingInfo: a!pagingInfo(
        startIndex: 1,
        batchSize: 50
      )
    ),
    fetchTotalCount: true
  ),
  
  local!count: local!boxers.totalCount - 1,
  local!index: odd(rand() * local!count),
  
  local!boxers.data[{local!index, local!index + 1}]
)

Hi everyone, 

this post doesn't provide any resolution to this topic, you can skip it if you want, here is just a bit of my bitter frustration :D 

Every now and then I find myself returning to this thread.

Hopefully, one day the miracle will happen, and Appian will include a break or continue in the foreach cycle. Or why not, do...while.

I can say that we could avoid a lot of unnecessary iteration if we had this, or for someone average like me, to be able to stop the looping simply, without resorting to recursion, sinister strategies or endless trial and error to limit the looping when you need it.... simply and easily (please notice the remarks about SIMPLICITY).

And I know that some people think “No. There is a reason it is called forEach”, but in other languages, someone (probably smarter/experienced than the average common citizen like me) did not agree and has thought of including the break for the foreach...just saying. 

Yes, yes, yes, I know, SAIL is declarative and there will be a million reasons to justify why we don't have a simple break in SAIL, but the result is that we don't have it.... and we'll have to deal with it.

Maybe something Appian could help with is shaping a recipe to deal with this challenge (whisper: hey, if there is any already, post it in this thread and mitigate my ignorance)

I'll be back here again in a couple of weeks....no doubt.