Group same field value when displaying

There isn't an easy way to have separate grid cells. What you can do is display your items in a list or add your down dividers. I have an example below.

a!localVariables(
  local!data: {
    a!map(
      col1: "Hello",
      col2: {
        "nested 1",
        "nested 2",
        "nested 3"
      }
    ),
    a!map(
      col1: "World",
      col2: {
        "nested 1",
        "nested 2",
        "nested 3"
      }
    )
  },
  a!gridLayout(
    label: "My Data",
    headerCells: {
      a!gridLayoutHeaderCell(
        label: "Column 1"
      ),
      a!gridLayoutHeaderCell(
        label: "Column 2"
      ),
      a!gridLayoutHeaderCell(
        label: "Column 2 - Alt"
      )
    },
    rows: a!forEach(
      local!data,
      a!gridRowLayout(
        contents: {
          a!textField(
            readOnly: true,
            value: fv!item.col1
          ),
          a!richTextDisplayField(
            value: a!richTextBulletedList(
              items: a!forEach(
                fv!item.col2,
                a!richTextItem(
                  text: fv!item
                )
              )
            )
          ),
          a!richTextDisplayField(
            value: a!forEach(
              fv!item.col2,
              a!richTextItem(
                text: fv!item&char(10)&"_________________________"&char(10)
              )
            )
          )
        }
      )
    )
  )
)