Data Entry

Something like this?

When you say this

Do you mean that the user stay on the same screen with a blank box to write new entry? If you want to write records at the same time you would need to use the writeRecords() function within the next button.

Write records in the next button or submit.

a!localVariables(
  local!data: 'recordType!{fb324deb-007c-495f-98dd-65e2ea1e6cdd}KS Record to Delete'(),
  {
    a!textField(
      label: "My Text",
      value: local!data['recordType!{fb324deb-007c-495f-98dd-65e2ea1e6cdd}KS Record to Delete.fields.{6436f9d3-5bce-4f75-b74a-ffa968c3ce41}name'],
      saveInto: {
        local!data['recordType!{fb324deb-007c-495f-98dd-65e2ea1e6cdd}KS Record to Delete.fields.{6436f9d3-5bce-4f75-b74a-ffa968c3ce41}name']
      }
    ),
    a!buttonLayout(
      primaryButtons: {
        a!buttonWidget(
          label: "Submit",
          saveInto: {
            a!writeRecords(
              records: local!data,
              onSuccess: a!save(
                local!data,
                'recordType!{fb324deb-007c-495f-98dd-65e2ea1e6cdd}KS Record to Delete'()
              )
            ),
            /*List a save which will close the user interface that captures the value*/
          },
          submit: true
        ),
        a!buttonWidget(
          label: "Add More",
          submit: false(),
          saveInto: {
            a!writeRecords(
              records: local!data,
              onSuccess: a!save(
                local!data,
                'recordType!{fb324deb-007c-495f-98dd-65e2ea1e6cdd}KS Record to Delete'()
              )
            )
          }
        )
      }
    )
  }
)

Write all values at once in a process.

/*Call this interface in a process model to write the records*/

a!localVariables(
  local!value,
  local!data,
  {
    a!textField(
      label: "My Text",
      value: local!value,
      saveInto: { local!value }
    ),
    a!buttonLayout(
      primaryButtons: {
        a!buttonWidget(
          label: "Submit",
          saveInto: {
            a!save(
              local!data,
              append(local!data, local!value)
            ),
            a!save(ri!records, local!data)
          },
          submit: true
        ),
        a!buttonWidget(
          label: "Add More",
          saveInto: {
            a!save(
              local!data,
              append(local!data, local!value)
            ),
            a!save(local!value, null)
          }
        )
      }
    )
  }
)

I would recommend using a process to write the records.

Just create that simple interface, make it the start form of a process, and add this process as an action to your site. This will work exactly as you described.